File : a-calend.ads
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT RUN-TIME COMPONENTS --
4 -- --
5 -- A D A . C A L E N D A R --
6 -- --
7 -- S p e c --
8 -- --
9 -- Copyright (C) 1992-2015, Free Software Foundation, Inc. --
10 -- --
11 -- This specification is derived from the Ada Reference Manual for use with --
12 -- GNAT. The copyright notice above, and the license provisions that follow --
13 -- apply solely to the contents of the part following the private keyword. --
14 -- --
15 -- GNAT is free software; you can redistribute it and/or modify it under --
16 -- terms of the GNU General Public License as published by the Free Soft- --
17 -- ware Foundation; either version 3, or (at your option) any later ver- --
18 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
19 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
20 -- or FITNESS FOR A PARTICULAR PURPOSE. --
21 -- --
22 -- --
23 -- --
24 -- --
25 -- --
26 -- You should have received a copy of the GNU General Public License and --
27 -- a copy of the GCC Runtime Library Exception along with this program; --
28 -- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
29 -- <http://www.gnu.org/licenses/>. --
30 -- --
31 -- GNAT was originally developed by the GNAT team at New York University. --
32 -- Extensive contributions were provided by Ada Core Technologies Inc. --
33 -- --
34 ------------------------------------------------------------------------------
35
36 package Ada.Calendar with
37 SPARK_Mode,
38 Abstract_State => (Clock_Time with Synchronous,
39 External => (Async_Readers,
40 Async_Writers)),
41 Initializes => Clock_Time
42 is
43
44 type Time is private;
45
46 -- Declarations representing limits of allowed local time values. Note that
47 -- these do NOT constrain the possible stored values of time which may well
48 -- permit a larger range of times (this is explicitly allowed in Ada 95).
49
50 subtype Year_Number is Integer range 1901 .. 2399;
51 subtype Month_Number is Integer range 1 .. 12;
52 subtype Day_Number is Integer range 1 .. 31;
53
54 -- A Day_Duration value of 86_400.0 designates a new day
55
56 subtype Day_Duration is Duration range 0.0 .. 86_400.0;
57
58 function Clock return Time with
59 Volatile_Function,
60 Global => Clock_Time;
61 -- The returned time value is the number of nanoseconds since the start
62 -- of Ada time (1901-01-01 00:00:00.0 UTC). If leap seconds are enabled,
63 -- the result will contain all elapsed leap seconds since the start of
64 -- Ada time until now.
65
66 function Year (Date : Time) return Year_Number;
67 function Month (Date : Time) return Month_Number;
68 function Day (Date : Time) return Day_Number;
69 function Seconds (Date : Time) return Day_Duration;
70
71 procedure Split
72 (Date : Time;
73 Year : out Year_Number;
74 Month : out Month_Number;
75 Day : out Day_Number;
76 Seconds : out Day_Duration);
77 -- Break down a time value into its date components set in the current
78 -- time zone. If Split is called on a time value created using Ada 2005
79 -- Time_Of in some arbitrary time zone, the input value will always be
80 -- interpreted as relative to the local time zone.
81
82 function Time_Of
83 (Year : Year_Number;
84 Month : Month_Number;
85 Day : Day_Number;
86 Seconds : Day_Duration := 0.0) return Time;
87 -- GNAT Note: Normally when procedure Split is called on a Time value
88 -- result of a call to function Time_Of, the out parameters of procedure
89 -- Split are identical to the in parameters of function Time_Of. However,
90 -- when a non-existent time of day is specified, the values for Seconds
91 -- may or may not be different. This may happen when Daylight Saving Time
92 -- (DST) is in effect, on the day when switching to DST, if Seconds
93 -- specifies a time of day in the hour that does not exist. For example,
94 -- in New York:
95 --
96 -- Time_Of (Year => 1998, Month => 4, Day => 5, Seconds => 10740.0)
97 --
98 -- will return a Time value T. If Split is called on T, the resulting
99 -- Seconds may be 14340.0 (3:59:00) instead of 10740.0 (2:59:00 being
100 -- a time that not exist).
101
102 function "+" (Left : Time; Right : Duration) return Time;
103 function "+" (Left : Duration; Right : Time) return Time;
104 function "-" (Left : Time; Right : Duration) return Time;
105 function "-" (Left : Time; Right : Time) return Duration;
106 -- The first three functions will raise Time_Error if the resulting time
107 -- value is less than the start of Ada time in UTC or greater than the
108 -- end of Ada time in UTC. The last function will raise Time_Error if the
109 -- resulting difference cannot fit into a duration value.
110
111 function "<" (Left, Right : Time) return Boolean;
112 function "<=" (Left, Right : Time) return Boolean;
113 function ">" (Left, Right : Time) return Boolean;
114 function ">=" (Left, Right : Time) return Boolean;
115
116 Time_Error : exception;
117
118 private
119 -- Mark the private part as SPARK_Mode Off to avoid accounting for variable
120 -- Invalid_Time_Zone_Offset in abstract state.
121
122 pragma SPARK_Mode (Off);
123
124 pragma Inline (Clock);
125
126 pragma Inline (Year);
127 pragma Inline (Month);
128 pragma Inline (Day);
129
130 pragma Inline ("+");
131 pragma Inline ("-");
132
133 pragma Inline ("<");
134 pragma Inline ("<=");
135 pragma Inline (">");
136 pragma Inline (">=");
137
138 -- The units used in this version of Ada.Calendar are nanoseconds. The
139 -- following constants provide values used in conversions of seconds or
140 -- days to the underlying units.
141
142 Nano : constant := 1_000_000_000;
143 Nano_F : constant := 1_000_000_000.0;
144 Nanos_In_Day : constant := 86_400_000_000_000;
145 Secs_In_Day : constant := 86_400;
146
147 ----------------------------
148 -- Implementation of Time --
149 ----------------------------
150
151 -- Time is represented as a signed 64 bit integer count of nanoseconds
152 -- since the start of Ada time (1901-01-01 00:00:00.0 UTC). Time values
153 -- produced by Time_Of are internally normalized to UTC regardless of their
154 -- local time zone. This representation ensures correct handling of leap
155 -- seconds as well as performing arithmetic. In Ada 95, Split and Time_Of
156 -- will treat a time value as being in the local time zone, in Ada 2005,
157 -- Split and Time_Of will treat a time value as being in the designated
158 -- time zone by the formal parameter or in UTC by default. The size of the
159 -- type is large enough to cover the Ada 2005 range of time (1901-01-01
160 -- 00:00:00.0 UTC - 2399-12-31-23:59:59.999999999 UTC).
161
162 ------------------
163 -- Leap Seconds --
164 ------------------
165
166 -- Due to Earth's slowdown, the astronomical time is not as precise as the
167 -- International Atomic Time. To compensate for this inaccuracy, a single
168 -- leap second is added after the last day of June or December. The count
169 -- of seconds during those occurrences becomes:
170
171 -- ... 58, 59, leap second 60, 0, 1, 2 ...
172
173 -- Unlike leap days, leap seconds occur simultaneously around the world.
174 -- In other words, if a leap second occurs at 23:59:60 UTC, it also occurs
175 -- on 18:59:60 -5 the same day or 2:59:60 +2 on the next day.
176
177 -- Leap seconds do not follow a formula. The International Earth Rotation
178 -- and Reference System Service decides when to add one. Leap seconds are
179 -- included in the representation of time in Ada 95 mode. As a result,
180 -- the following two time values will differ by two seconds:
181
182 -- 1972-06-30 23:59:59.0
183 -- 1972-07-01 00:00:00.0
184
185 -- When a new leap second is introduced, the following steps must be
186 -- carried out:
187
188 -- 1) Increment Leap_Seconds_Count in a-calend.adb by one
189 -- 2) Increment LS_Count in xleaps.adb by one
190 -- 3) Add the new date to the aggregate of array LS_Dates in
191 -- xleaps.adb
192 -- 4) Compile and execute xleaps
193 -- 5) Replace the values of Leap_Second_Times in a-calend.adb with the
194 -- aggregate generated by xleaps
195
196 -- The algorithms that build the actual leap second values and discover
197 -- how many leap seconds have occurred between two dates do not need any
198 -- modification.
199
200 ------------------------------
201 -- Non-leap Centennial Years --
202 ------------------------------
203
204 -- Over the range of Ada time, centennial years 2100, 2200 and 2300 are
205 -- non-leap. As a consequence, seven non-leap years occur over the period
206 -- of year - 4 to year + 4. Internally, routines Split and Time_Of add or
207 -- subtract a "fake" February 29 to facilitate the arithmetic involved.
208
209 ------------------------
210 -- Local Declarations --
211 ------------------------
212
213 type Time_Rep is new Long_Long_Integer;
214 type Time is new Time_Rep;
215 -- The underlying type of Time has been chosen to be a 64 bit signed
216 -- integer number since it allows for easier processing of sub-seconds
217 -- and arithmetic. We use Long_Long_Integer to allow this unit to compile
218 -- when using custom target configuration files where the max integer is
219 -- 32 bits. This is useful for static analysis tools such as SPARK or
220 -- CodePeer.
221 --
222 -- Note: the reason we have two separate types here is to avoid problems
223 -- with overloading ambiguities in the body if we tried to use Time as an
224 -- internal computational type.
225
226 Days_In_Month : constant array (Month_Number) of Day_Number :=
227 (31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31);
228 -- Days in month for non-leap year, leap year case is adjusted in code
229
230 Invalid_Time_Zone_Offset : Long_Integer;
231 pragma Import (C, Invalid_Time_Zone_Offset, "__gnat_invalid_tzoff");
232
233 function Is_Leap (Year : Year_Number) return Boolean;
234 -- Determine whether a given year is leap
235
236 ----------------------------------------------------------
237 -- Target-Independent Interface to Children of Calendar --
238 ----------------------------------------------------------
239
240 -- The following packages provide a target-independent interface to the
241 -- children of Calendar - Arithmetic, Conversions, Delays, Formatting and
242 -- Time_Zones.
243
244 ---------------------------
245 -- Arithmetic_Operations --
246 ---------------------------
247
248 package Arithmetic_Operations is
249
250 function Add (Date : Time; Days : Long_Integer) return Time;
251 -- Add a certain number of days to a time value
252
253 procedure Difference
254 (Left : Time;
255 Right : Time;
256 Days : out Long_Integer;
257 Seconds : out Duration;
258 Leap_Seconds : out Integer);
259 -- Calculate the difference between two time values in terms of days,
260 -- seconds and leap seconds elapsed. The leap seconds are not included
261 -- in the seconds returned. If Left is greater than Right, the returned
262 -- values are positive, negative otherwise.
263
264 function Subtract (Date : Time; Days : Long_Integer) return Time;
265 -- Subtract a certain number of days from a time value
266
267 end Arithmetic_Operations;
268
269 ---------------------------
270 -- Conversion_Operations --
271 ---------------------------
272
273 package Conversion_Operations is
274
275 function To_Ada_Time (Unix_Time : Long_Integer) return Time;
276 -- Unix to Ada Epoch conversion
277
278 function To_Ada_Time
279 (tm_year : Integer;
280 tm_mon : Integer;
281 tm_day : Integer;
282 tm_hour : Integer;
283 tm_min : Integer;
284 tm_sec : Integer;
285 tm_isdst : Integer) return Time;
286 -- Struct tm to Ada Epoch conversion
287
288 function To_Duration
289 (tv_sec : Long_Integer;
290 tv_nsec : Long_Integer) return Duration;
291 -- Struct timespec to Duration conversion
292
293 procedure To_Struct_Timespec
294 (D : Duration;
295 tv_sec : out Long_Integer;
296 tv_nsec : out Long_Integer);
297 -- Duration to struct timespec conversion
298
299 procedure To_Struct_Tm
300 (T : Time;
301 tm_year : out Integer;
302 tm_mon : out Integer;
303 tm_day : out Integer;
304 tm_hour : out Integer;
305 tm_min : out Integer;
306 tm_sec : out Integer);
307 -- Time to struct tm conversion
308
309 function To_Unix_Time (Ada_Time : Time) return Long_Integer;
310 -- Ada to Unix Epoch conversion
311
312 end Conversion_Operations;
313
314 ----------------------
315 -- Delay_Operations --
316 ----------------------
317
318 package Delay_Operations is
319
320 function To_Duration (Date : Time) return Duration;
321 -- Given a time value in nanoseconds since 1901, convert it into a
322 -- duration value giving the number of nanoseconds since the Unix Epoch.
323
324 end Delay_Operations;
325
326 ---------------------------
327 -- Formatting_Operations --
328 ---------------------------
329
330 package Formatting_Operations is
331
332 function Day_Of_Week (Date : Time) return Integer;
333 -- Determine which day of week Date falls on. The returned values are
334 -- within the range of 0 .. 6 (Monday .. Sunday).
335
336 procedure Split
337 (Date : Time;
338 Year : out Year_Number;
339 Month : out Month_Number;
340 Day : out Day_Number;
341 Day_Secs : out Day_Duration;
342 Hour : out Integer;
343 Minute : out Integer;
344 Second : out Integer;
345 Sub_Sec : out Duration;
346 Leap_Sec : out Boolean;
347 Use_TZ : Boolean;
348 Is_Historic : Boolean;
349 Time_Zone : Long_Integer);
350 pragma Export (Ada, Split, "__gnat_split");
351 -- Split a time value into its components. If flag Is_Historic is set,
352 -- this routine would try to use to the best of the OS's abilities the
353 -- time zone offset that was or will be in effect on Date. Set Use_TZ
354 -- to use the local time zone (the value in Time_Zone is ignored) when
355 -- splitting a time value.
356
357 function Time_Of
358 (Year : Year_Number;
359 Month : Month_Number;
360 Day : Day_Number;
361 Day_Secs : Day_Duration;
362 Hour : Integer;
363 Minute : Integer;
364 Second : Integer;
365 Sub_Sec : Duration;
366 Leap_Sec : Boolean;
367 Use_Day_Secs : Boolean;
368 Use_TZ : Boolean;
369 Is_Historic : Boolean;
370 Time_Zone : Long_Integer) return Time;
371 pragma Export (Ada, Time_Of, "__gnat_time_of");
372 -- Given all the components of a date, return the corresponding time
373 -- value. Set Use_Day_Secs to use the value in Day_Secs, otherwise the
374 -- day duration will be calculated from Hour, Minute, Second and Sub_
375 -- Sec. If flag Is_Historic is set, this routine would try to use to the
376 -- best of the OS's abilities the time zone offset that was or will be
377 -- in effect on the input date. Set Use_TZ to use the local time zone
378 -- (the value in formal Time_Zone is ignored) when building a time value
379 -- and to verify the validity of a requested leap second.
380
381 end Formatting_Operations;
382
383 ---------------------------
384 -- Time_Zones_Operations --
385 ---------------------------
386
387 package Time_Zones_Operations is
388
389 function UTC_Time_Offset (Date : Time) return Long_Integer;
390 -- Return (in seconds) the difference between the local time zone and
391 -- UTC time at a specific historic date.
392
393 end Time_Zones_Operations;
394
395 end Ada.Calendar;