File : a-cusyqu.ads
1 ------------------------------------------------------------------------------
2 -- --
3 -- GNAT LIBRARY COMPONENTS --
4 -- --
5 -- ADA.CONTAINERS.UNBOUNDED_SYNCHRONIZED_QUEUES --
6 -- --
7 -- S p e c --
8 -- --
9 -- Copyright (C) 2011-2015, Free Software Foundation, Inc. --
10 -- --
11 -- This specification is derived from the Ada Reference Manual for use with --
12 -- GNAT. The copyright notice above, and the license provisions that follow --
13 -- apply solely to the contents of the part following the private keyword. --
14 -- --
15 -- GNAT is free software; you can redistribute it and/or modify it under --
16 -- terms of the GNU General Public License as published by the Free Soft- --
17 -- ware Foundation; either version 3, or (at your option) any later ver- --
18 -- sion. GNAT is distributed in the hope that it will be useful, but WITH- --
19 -- OUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY --
20 -- or FITNESS FOR A PARTICULAR PURPOSE. --
21 -- --
22 -- --
23 -- --
24 -- --
25 -- --
26 -- You should have received a copy of the GNU General Public License and --
27 -- a copy of the GCC Runtime Library Exception along with this program; --
28 -- see the files COPYING3 and COPYING.RUNTIME respectively. If not, see --
29 -- <http://www.gnu.org/licenses/>. --
30 -- --
31 -- This unit was originally developed by Matthew J Heaney. --
32 ------------------------------------------------------------------------------
33
34 with System;
35 with Ada.Containers.Synchronized_Queue_Interfaces;
36 with Ada.Finalization;
37
38 generic
39 with package Queue_Interfaces is
40 new Ada.Containers.Synchronized_Queue_Interfaces (<>);
41
42 Default_Ceiling : System.Any_Priority := System.Priority'Last;
43
44 package Ada.Containers.Unbounded_Synchronized_Queues is
45 pragma Annotate (CodePeer, Skip_Analysis);
46 pragma Preelaborate;
47
48 package Implementation is
49
50 -- All identifiers in this unit are implementation defined
51
52 pragma Implementation_Defined;
53
54 type List_Type is tagged limited private;
55
56 procedure Enqueue
57 (List : in out List_Type;
58 New_Item : Queue_Interfaces.Element_Type);
59
60 procedure Dequeue
61 (List : in out List_Type;
62 Element : out Queue_Interfaces.Element_Type);
63
64 function Length (List : List_Type) return Count_Type;
65
66 function Max_Length (List : List_Type) return Count_Type;
67
68 private
69
70 type Node_Type;
71 type Node_Access is access Node_Type;
72
73 type Node_Type is limited record
74 Element : Queue_Interfaces.Element_Type;
75 Next : Node_Access;
76 end record;
77
78 type List_Type is new Ada.Finalization.Limited_Controlled with record
79 First, Last : Node_Access;
80 Length : Count_Type := 0;
81 Max_Length : Count_Type := 0;
82 end record;
83
84 overriding procedure Finalize (List : in out List_Type);
85
86 end Implementation;
87
88 protected type Queue
89 (Ceiling : System.Any_Priority := Default_Ceiling)
90 with
91 Priority => Ceiling
92 is new Queue_Interfaces.Queue with
93
94 overriding entry Enqueue (New_Item : Queue_Interfaces.Element_Type);
95
96 overriding entry Dequeue (Element : out Queue_Interfaces.Element_Type);
97
98 overriding function Current_Use return Count_Type;
99
100 overriding function Peak_Use return Count_Type;
101
102 private
103 List : Implementation.List_Type;
104 end Queue;
105
106 end Ada.Containers.Unbounded_Synchronized_Queues;