File : sem_warn.adb


   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ W A R N                              --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25 
  26 with Atree;    use Atree;
  27 with Debug;    use Debug;
  28 with Einfo;    use Einfo;
  29 with Errout;   use Errout;
  30 with Exp_Code; use Exp_Code;
  31 with Fname;    use Fname;
  32 with Lib;      use Lib;
  33 with Lib.Xref; use Lib.Xref;
  34 with Namet;    use Namet;
  35 with Nlists;   use Nlists;
  36 with Opt;      use Opt;
  37 with Par_SCO;  use Par_SCO;
  38 with Rtsfind;  use Rtsfind;
  39 with Sem;      use Sem;
  40 with Sem_Ch8;  use Sem_Ch8;
  41 with Sem_Aux;  use Sem_Aux;
  42 with Sem_Eval; use Sem_Eval;
  43 with Sem_Prag; use Sem_Prag;
  44 with Sem_Util; use Sem_Util;
  45 with Sinfo;    use Sinfo;
  46 with Sinput;   use Sinput;
  47 with Snames;   use Snames;
  48 with Stand;    use Stand;
  49 with Stringt;  use Stringt;
  50 with Uintp;    use Uintp;
  51 
  52 package body Sem_Warn is
  53 
  54    --  The following table collects Id's of entities that are potentially
  55    --  unreferenced. See Check_Unset_Reference for further details.
  56    --  ??? Check_Unset_Reference has zero information about this table.
  57 
  58    package Unreferenced_Entities is new Table.Table (
  59      Table_Component_Type => Entity_Id,
  60      Table_Index_Type     => Nat,
  61      Table_Low_Bound      => 1,
  62      Table_Initial        => Alloc.Unreferenced_Entities_Initial,
  63      Table_Increment      => Alloc.Unreferenced_Entities_Increment,
  64      Table_Name           => "Unreferenced_Entities");
  65 
  66    --  The following table collects potential warnings for IN OUT parameters
  67    --  that are referenced but not modified. These warnings are processed when
  68    --  the front end calls the procedure Output_Non_Modified_In_Out_Warnings.
  69    --  The reason that we defer output of these messages is that we want to
  70    --  detect the case where the relevant procedure is used as a generic actual
  71    --  in an instantiation, since we suppress the warnings in this case. The
  72    --  flag Used_As_Generic_Actual will be set in this case, but only at the
  73    --  point of usage. Similarly, we suppress the message if the address of the
  74    --  procedure is taken, where the flag Address_Taken may be set later.
  75 
  76    package In_Out_Warnings is new Table.Table (
  77      Table_Component_Type => Entity_Id,
  78      Table_Index_Type     => Nat,
  79      Table_Low_Bound      => 1,
  80      Table_Initial        => Alloc.In_Out_Warnings_Initial,
  81      Table_Increment      => Alloc.In_Out_Warnings_Increment,
  82      Table_Name           => "In_Out_Warnings");
  83 
  84    --------------------------------------------------------
  85    -- Handling of Warnings Off, Unmodified, Unreferenced --
  86    --------------------------------------------------------
  87 
  88    --  The functions Has_Warnings_Off, Has_Unmodified, Has_Unreferenced must
  89    --  generally be used instead of Warnings_Off, Has_Pragma_Unmodified and
  90    --  Has_Pragma_Unreferenced, as noted in the specs in Einfo.
  91 
  92    --  In order to avoid losing warnings in -gnatw.w (warn on unnecessary
  93    --  warnings off pragma) mode, i.e. to avoid false negatives, the code
  94    --  must follow some important rules.
  95 
  96    --  Call these functions as late as possible, after completing all other
  97    --  tests, just before the warnings is given. For example, don't write:
  98 
  99    --     if not Has_Warnings_Off (E)
 100    --       and then some-other-predicate-on-E then ..
 101 
 102    --  Instead the following is preferred
 103 
 104    --     if some-other-predicate-on-E
 105    --       and then Has_Warnings_Off (E)
 106 
 107    --  This way if some-other-predicate is false, we avoid a false indication
 108    --  that a Warnings (Off, E) pragma was useful in preventing a warning.
 109 
 110    --  The second rule is that if both Has_Unmodified and Has_Warnings_Off, or
 111    --  Has_Unreferenced and Has_Warnings_Off are called, make sure that the
 112    --  call to Has_Unmodified/Has_Unreferenced comes first, this way we record
 113    --  that the Warnings (Off) could have been Unreferenced or Unmodified. In
 114    --  fact Has_Unmodified/Has_Unreferenced includes a test for Warnings Off,
 115    --  and so a subsequent test is not needed anyway (though it is harmless).
 116 
 117    -----------------------
 118    -- Local Subprograms --
 119    -----------------------
 120 
 121    function Generic_Package_Spec_Entity (E : Entity_Id) return Boolean;
 122    --  This returns true if the entity E is declared within a generic package.
 123    --  The point of this is to detect variables which are not assigned within
 124    --  the generic, but might be assigned outside the package for any given
 125    --  instance. These are cases where we leave the warnings to be posted for
 126    --  the instance, when we will know more.
 127 
 128    function Goto_Spec_Entity (E : Entity_Id) return Entity_Id;
 129    --  If E is a parameter entity for a subprogram body, then this function
 130    --  returns the corresponding spec entity, if not, E is returned unchanged.
 131 
 132    function Has_Pragma_Unmodified_Check_Spec (E : Entity_Id) return Boolean;
 133    --  Tests Has_Pragma_Unmodified flag for entity E. If E is not a formal,
 134    --  this is simply the setting of the flag Has_Pragma_Unmodified. If E is
 135    --  a body formal, the setting of the flag in the corresponding spec is
 136    --  also checked (and True returned if either flag is True).
 137 
 138    function Has_Pragma_Unreferenced_Check_Spec (E : Entity_Id) return Boolean;
 139    --  Tests Has_Pragma_Unreferenced flag for entity E. If E is not a formal,
 140    --  this is simply the setting of the flag Has_Pragma_Unreferenced. If E is
 141    --  a body formal, the setting of the flag in the corresponding spec is
 142    --  also checked (and True returned if either flag is True).
 143 
 144    function Never_Set_In_Source_Check_Spec (E : Entity_Id) return Boolean;
 145    --  Tests Never_Set_In_Source status for entity E. If E is not a formal,
 146    --  this is simply the setting of the flag Never_Set_In_Source. If E is
 147    --  a body formal, the setting of the flag in the corresponding spec is
 148    --  also checked (and False returned if either flag is False).
 149 
 150    function Operand_Has_Warnings_Suppressed (N : Node_Id) return Boolean;
 151    --  This function traverses the expression tree represented by the node N
 152    --  and determines if any sub-operand is a reference to an entity for which
 153    --  the Warnings_Off flag is set. True is returned if such an entity is
 154    --  encountered, and False otherwise.
 155 
 156    function Referenced_Check_Spec (E : Entity_Id) return Boolean;
 157    --  Tests Referenced status for entity E. If E is not a formal, this is
 158    --  simply the setting of the flag Referenced. If E is a body formal, the
 159    --  setting of the flag in the corresponding spec is also checked (and True
 160    --  returned if either flag is True).
 161 
 162    function Referenced_As_LHS_Check_Spec (E : Entity_Id) return Boolean;
 163    --  Tests Referenced_As_LHS status for entity E. If E is not a formal, this
 164    --  is simply the setting of the flag Referenced_As_LHS. If E is a body
 165    --  formal, the setting of the flag in the corresponding spec is also
 166    --  checked (and True returned if either flag is True).
 167 
 168    function Referenced_As_Out_Parameter_Check_Spec
 169      (E : Entity_Id) return Boolean;
 170    --  Tests Referenced_As_Out_Parameter status for entity E. If E is not a
 171    --  formal, this is simply the setting of Referenced_As_Out_Parameter. If E
 172    --  is a body formal, the setting of the flag in the corresponding spec is
 173    --  also checked (and True returned if either flag is True).
 174 
 175    procedure Warn_On_Unreferenced_Entity
 176      (Spec_E : Entity_Id;
 177       Body_E : Entity_Id := Empty);
 178    --  Output warnings for unreferenced entity E. For the case of an entry
 179    --  formal, Body_E is the corresponding body entity for a particular
 180    --  accept statement, and the message is posted on Body_E. In all other
 181    --  cases, Body_E is ignored and must be Empty.
 182 
 183    function Warnings_Off_Check_Spec (E : Entity_Id) return Boolean;
 184    --  Returns True if Warnings_Off is set for the entity E or (in the case
 185    --  where there is a Spec_Entity), Warnings_Off is set for the Spec_Entity.
 186 
 187    --------------------------
 188    -- Check_Code_Statement --
 189    --------------------------
 190 
 191    procedure Check_Code_Statement (N : Node_Id) is
 192    begin
 193       --  If volatile, nothing to worry about
 194 
 195       if Is_Asm_Volatile (N) then
 196          return;
 197       end if;
 198 
 199       --  Warn if no input or no output
 200 
 201       Setup_Asm_Inputs (N);
 202 
 203       if No (Asm_Input_Value) then
 204          Error_Msg_F
 205            ("??code statement with no inputs should usually be Volatile!", N);
 206          return;
 207       end if;
 208 
 209       Setup_Asm_Outputs (N);
 210 
 211       if No (Asm_Output_Variable) then
 212          Error_Msg_F
 213            ("??code statement with no outputs should usually be Volatile!", N);
 214          return;
 215       end if;
 216    end Check_Code_Statement;
 217 
 218    ---------------------------------
 219    -- Check_Infinite_Loop_Warning --
 220    ---------------------------------
 221 
 222    --  The case we look for is a while loop which tests a local variable, where
 223    --  there is no obvious direct or possible indirect update of the variable
 224    --  within the body of the loop.
 225 
 226    procedure Check_Infinite_Loop_Warning (Loop_Statement : Node_Id) is
 227       Expression : Node_Id := Empty;
 228       --  Set to WHILE or EXIT WHEN condition to be tested
 229 
 230       Ref : Node_Id := Empty;
 231       --  Reference in Expression to variable that might not be modified
 232       --  in loop, indicating a possible infinite loop.
 233 
 234       Var : Entity_Id := Empty;
 235       --  Corresponding entity (entity of Ref)
 236 
 237       Function_Call_Found : Boolean := False;
 238       --  True if Find_Var found a function call in the condition
 239 
 240       procedure Find_Var (N : Node_Id);
 241       --  Inspect condition to see if it depends on a single entity reference.
 242       --  If so, Ref is set to point to the reference node, and Var is set to
 243       --  the referenced Entity.
 244 
 245       function Has_Indirection (T : Entity_Id) return Boolean;
 246       --  If the controlling variable is an access type, or is a record type
 247       --  with access components, assume that it is changed indirectly and
 248       --  suppress the warning. As a concession to low-level programming, in
 249       --  particular within Declib, we also suppress warnings on a record
 250       --  type that contains components of type Address or Short_Address.
 251 
 252       function Is_Suspicious_Function_Name (E : Entity_Id) return Boolean;
 253       --  Given an entity name, see if the name appears to have something to
 254       --  do with I/O or network stuff, and if so, return True. Used to kill
 255       --  some false positives on a heuristic basis that such functions will
 256       --  likely have some strange side effect dependencies. A rather strange
 257       --  test, but warning messages are in the heuristics business.
 258 
 259       function Test_Ref (N : Node_Id) return Traverse_Result;
 260       --  Test for reference to variable in question. Returns Abandon if
 261       --  matching reference found. Used in instantiation of No_Ref_Found.
 262 
 263       function No_Ref_Found is new Traverse_Func (Test_Ref);
 264       --  Function to traverse body of procedure. Returns Abandon if matching
 265       --  reference found.
 266 
 267       --------------
 268       -- Find_Var --
 269       --------------
 270 
 271       procedure Find_Var (N : Node_Id) is
 272       begin
 273          --  Condition is a direct variable reference
 274 
 275          if Is_Entity_Name (N) then
 276             Ref := N;
 277             Var := Entity (Ref);
 278 
 279          --  Case of condition is a comparison with compile time known value
 280 
 281          elsif Nkind (N) in N_Op_Compare then
 282             if Compile_Time_Known_Value (Right_Opnd (N)) then
 283                Find_Var (Left_Opnd (N));
 284 
 285             elsif Compile_Time_Known_Value (Left_Opnd (N)) then
 286                Find_Var (Right_Opnd (N));
 287 
 288             --  Ignore any other comparison
 289 
 290             else
 291                return;
 292             end if;
 293 
 294          --  If condition is a negation, check its operand
 295 
 296          elsif Nkind (N) = N_Op_Not then
 297             Find_Var (Right_Opnd (N));
 298 
 299          --  Case of condition is function call
 300 
 301          elsif Nkind (N) = N_Function_Call then
 302 
 303             Function_Call_Found := True;
 304 
 305             --  Forget it if function name is not entity, who knows what
 306             --  we might be calling?
 307 
 308             if not Is_Entity_Name (Name (N)) then
 309                return;
 310 
 311             --  Forget it if function name is suspicious. A strange test
 312             --  but warning generation is in the heuristics business.
 313 
 314             elsif Is_Suspicious_Function_Name (Entity (Name (N))) then
 315                return;
 316 
 317             --  Forget it if warnings are suppressed on function entity
 318 
 319             elsif Has_Warnings_Off (Entity (Name (N))) then
 320                return;
 321             end if;
 322 
 323             --  OK, see if we have one argument
 324 
 325             declare
 326                PA : constant List_Id := Parameter_Associations (N);
 327 
 328             begin
 329                --  One argument, so check the argument
 330 
 331                if Present (PA) and then List_Length (PA) = 1 then
 332                   if Nkind (First (PA)) = N_Parameter_Association then
 333                      Find_Var (Explicit_Actual_Parameter (First (PA)));
 334                   else
 335                      Find_Var (First (PA));
 336                   end if;
 337 
 338                --  Not one argument
 339 
 340                else
 341                   return;
 342                end if;
 343             end;
 344 
 345          --  Any other kind of node is not something we warn for
 346 
 347          else
 348             return;
 349          end if;
 350       end Find_Var;
 351 
 352       ---------------------
 353       -- Has_Indirection --
 354       ---------------------
 355 
 356       function Has_Indirection (T : Entity_Id) return Boolean is
 357          Comp : Entity_Id;
 358          Rec  : Entity_Id;
 359 
 360       begin
 361          if Is_Access_Type (T) then
 362             return True;
 363 
 364          elsif Is_Private_Type (T)
 365            and then Present (Full_View (T))
 366            and then Is_Access_Type (Full_View (T))
 367          then
 368             return True;
 369 
 370          elsif Is_Record_Type (T) then
 371             Rec := T;
 372 
 373          elsif Is_Private_Type (T)
 374            and then Present (Full_View (T))
 375            and then Is_Record_Type (Full_View (T))
 376          then
 377             Rec := Full_View (T);
 378          else
 379             return False;
 380          end if;
 381 
 382          Comp := First_Component (Rec);
 383          while Present (Comp) loop
 384             if Is_Access_Type (Etype (Comp))
 385               or else Is_Descendant_Of_Address (Etype (Comp))
 386             then
 387                return True;
 388             end if;
 389 
 390             Next_Component (Comp);
 391          end loop;
 392 
 393          return False;
 394       end Has_Indirection;
 395 
 396       ---------------------------------
 397       -- Is_Suspicious_Function_Name --
 398       ---------------------------------
 399 
 400       function Is_Suspicious_Function_Name (E : Entity_Id) return Boolean is
 401          S : Entity_Id;
 402 
 403          function Substring_Present (S : String) return Boolean;
 404          --  Returns True if name buffer has given string delimited by non-
 405          --  alphabetic characters or by end of string. S is lower case.
 406 
 407          -----------------------
 408          -- Substring_Present --
 409          -----------------------
 410 
 411          function Substring_Present (S : String) return Boolean is
 412             Len : constant Natural := S'Length;
 413 
 414          begin
 415             for J in 1 .. Name_Len - (Len - 1) loop
 416                if Name_Buffer (J .. J + (Len - 1)) = S
 417                  and then (J = 1 or else Name_Buffer (J - 1) not in 'a' .. 'z')
 418                  and then
 419                    (J + Len > Name_Len
 420                      or else Name_Buffer (J + Len) not in 'a' .. 'z')
 421                then
 422                   return True;
 423                end if;
 424             end loop;
 425 
 426             return False;
 427          end Substring_Present;
 428 
 429       --  Start of processing for Is_Suspicious_Function_Name
 430 
 431       begin
 432          S := E;
 433          while Present (S) and then S /= Standard_Standard loop
 434             Get_Name_String (Chars (S));
 435 
 436             if Substring_Present ("io")
 437               or else Substring_Present ("file")
 438               or else Substring_Present ("network")
 439             then
 440                return True;
 441             else
 442                S := Scope (S);
 443             end if;
 444          end loop;
 445 
 446          return False;
 447       end Is_Suspicious_Function_Name;
 448 
 449       --------------
 450       -- Test_Ref --
 451       --------------
 452 
 453       function Test_Ref (N : Node_Id) return Traverse_Result is
 454       begin
 455          --  Waste of time to look at the expression we are testing
 456 
 457          if N = Expression then
 458             return Skip;
 459 
 460          --  Direct reference to variable in question
 461 
 462          elsif Is_Entity_Name (N)
 463            and then Present (Entity (N))
 464            and then Entity (N) = Var
 465          then
 466             --  If this is an lvalue, then definitely abandon, since
 467             --  this could be a direct modification of the variable.
 468 
 469             if May_Be_Lvalue (N) then
 470                return Abandon;
 471             end if;
 472 
 473             --  If the condition contains a function call, we consider it may
 474             --  be modified by side-effects from a procedure call. Otherwise,
 475             --  we consider the condition may not be modified, although that
 476             --  might happen if Variable is itself a by-reference parameter,
 477             --  and the procedure called modifies the global object referred to
 478             --  by Variable, but we actually prefer to issue a warning in this
 479             --  odd case. Note that the case where the procedure called has
 480             --  visibility over Variable is treated in another case below.
 481 
 482             if Function_Call_Found then
 483                declare
 484                   P : Node_Id;
 485 
 486                begin
 487                   P := N;
 488                   loop
 489                      P := Parent (P);
 490                      exit when P = Loop_Statement;
 491 
 492                      --  Abandon if at procedure call, or something strange is
 493                      --  going on (perhaps a node with no parent that should
 494                      --  have one but does not?) As always, for a warning we
 495                      --  prefer to just abandon the warning than get into the
 496                      --  business of complaining about the tree structure here.
 497 
 498                      if No (P)
 499                        or else Nkind (P) = N_Procedure_Call_Statement
 500                      then
 501                         return Abandon;
 502                      end if;
 503                   end loop;
 504                end;
 505             end if;
 506 
 507          --  Reference to variable renaming variable in question
 508 
 509          elsif Is_Entity_Name (N)
 510            and then Present (Entity (N))
 511            and then Ekind (Entity (N)) = E_Variable
 512            and then Present (Renamed_Object (Entity (N)))
 513            and then Is_Entity_Name (Renamed_Object (Entity (N)))
 514            and then Entity (Renamed_Object (Entity (N))) = Var
 515            and then May_Be_Lvalue (N)
 516          then
 517             return Abandon;
 518 
 519          --  Call to subprogram
 520 
 521          elsif Nkind (N) in N_Subprogram_Call then
 522 
 523             --  If subprogram is within the scope of the entity we are dealing
 524             --  with as the loop variable, then it could modify this parameter,
 525             --  so we abandon in this case. In the case of a subprogram that is
 526             --  not an entity we also abandon. The check for no entity being
 527             --  present is a defense against previous errors.
 528 
 529             if not Is_Entity_Name (Name (N))
 530               or else No (Entity (Name (N)))
 531               or else Scope_Within (Entity (Name (N)), Scope (Var))
 532             then
 533                return Abandon;
 534             end if;
 535 
 536             --  If any of the arguments are of type access to subprogram, then
 537             --  we may have funny side effects, so no warning in this case.
 538 
 539             declare
 540                Actual : Node_Id;
 541             begin
 542                Actual := First_Actual (N);
 543                while Present (Actual) loop
 544                   if Is_Access_Subprogram_Type (Etype (Actual)) then
 545                      return Abandon;
 546                   else
 547                      Next_Actual (Actual);
 548                   end if;
 549                end loop;
 550             end;
 551 
 552          --  Declaration of the variable in question
 553 
 554          elsif Nkind (N) = N_Object_Declaration
 555            and then Defining_Identifier (N) = Var
 556          then
 557             return Abandon;
 558          end if;
 559 
 560          --  All OK, continue scan
 561 
 562          return OK;
 563       end Test_Ref;
 564 
 565    --  Start of processing for Check_Infinite_Loop_Warning
 566 
 567    begin
 568       --  Skip processing if debug flag gnatd.w is set
 569 
 570       if Debug_Flag_Dot_W then
 571          return;
 572       end if;
 573 
 574       --  Deal with Iteration scheme present
 575 
 576       declare
 577          Iter : constant Node_Id := Iteration_Scheme (Loop_Statement);
 578 
 579       begin
 580          if Present (Iter) then
 581 
 582             --  While iteration
 583 
 584             if Present (Condition (Iter)) then
 585 
 586                --  Skip processing for while iteration with conditions actions,
 587                --  since they make it too complicated to get the warning right.
 588 
 589                if Present (Condition_Actions (Iter)) then
 590                   return;
 591                end if;
 592 
 593                --  Capture WHILE condition
 594 
 595                Expression := Condition (Iter);
 596 
 597             --  For iteration, do not process, since loop will always terminate
 598 
 599             elsif Present (Loop_Parameter_Specification (Iter)) then
 600                return;
 601             end if;
 602          end if;
 603       end;
 604 
 605       --  Check chain of EXIT statements, we only process loops that have a
 606       --  single exit condition (either a single EXIT WHEN statement, or a
 607       --  WHILE loop not containing any EXIT WHEN statements).
 608 
 609       declare
 610          Ident     : constant Node_Id := Identifier (Loop_Statement);
 611          Exit_Stmt : Node_Id;
 612 
 613       begin
 614          --  If we don't have a proper chain set, ignore call entirely. This
 615          --  happens because of previous errors.
 616 
 617          if No (Entity (Ident))
 618            or else Ekind (Entity (Ident)) /= E_Loop
 619          then
 620             Check_Error_Detected;
 621             return;
 622          end if;
 623 
 624          --  Otherwise prepare to scan list of EXIT statements
 625 
 626          Exit_Stmt := First_Exit_Statement (Entity (Ident));
 627          while Present (Exit_Stmt) loop
 628 
 629             --  Check for EXIT WHEN
 630 
 631             if Present (Condition (Exit_Stmt)) then
 632 
 633                --  Quit processing if EXIT WHEN in WHILE loop, or more than
 634                --  one EXIT WHEN statement present in the loop.
 635 
 636                if Present (Expression) then
 637                   return;
 638 
 639                --  Otherwise capture condition from EXIT WHEN statement
 640 
 641                else
 642                   Expression := Condition (Exit_Stmt);
 643                end if;
 644 
 645             --  If an unconditional exit statement is the last statement in the
 646             --  loop, assume that no warning is needed, without any attempt at
 647             --  checking whether the exit is reachable.
 648 
 649             elsif Exit_Stmt = Last (Statements (Loop_Statement)) then
 650                return;
 651             end if;
 652 
 653             Exit_Stmt := Next_Exit_Statement (Exit_Stmt);
 654          end loop;
 655       end;
 656 
 657       --  Return if no condition to test
 658 
 659       if No (Expression) then
 660          return;
 661       end if;
 662 
 663       --  Initial conditions met, see if condition is of right form
 664 
 665       Find_Var (Expression);
 666 
 667       --  Nothing to do if local variable from source not found. If it's a
 668       --  renaming, it is probably renaming something too complicated to deal
 669       --  with here.
 670 
 671       if No (Var)
 672         or else Ekind (Var) /= E_Variable
 673         or else Is_Library_Level_Entity (Var)
 674         or else not Comes_From_Source (Var)
 675         or else Nkind (Parent (Var)) = N_Object_Renaming_Declaration
 676       then
 677          return;
 678 
 679       --  Nothing to do if there is some indirection involved (assume that the
 680       --  designated variable might be modified in some way we don't see).
 681       --  However, if no function call was found, then we don't care about
 682       --  indirections, because the condition must be something like "while X
 683       --  /= null loop", so we don't care if X.all is modified in the loop.
 684 
 685       elsif Function_Call_Found and then Has_Indirection (Etype (Var)) then
 686          return;
 687 
 688       --  Same sort of thing for volatile variable, might be modified by
 689       --  some other task or by the operating system in some way.
 690 
 691       elsif Is_Volatile (Var) then
 692          return;
 693       end if;
 694 
 695       --  Filter out case of original statement sequence starting with delay.
 696       --  We assume this is a multi-tasking program and that the condition
 697       --  is affected by other threads (some kind of busy wait).
 698 
 699       declare
 700          Fstm : constant Node_Id :=
 701                   Original_Node (First (Statements (Loop_Statement)));
 702       begin
 703          if Nkind (Fstm) = N_Delay_Relative_Statement
 704            or else Nkind (Fstm) = N_Delay_Until_Statement
 705          then
 706             return;
 707          end if;
 708       end;
 709 
 710       --  We have a variable reference of the right form, now we scan the loop
 711       --  body to see if it looks like it might not be modified
 712 
 713       if No_Ref_Found (Loop_Statement) = OK then
 714          Error_Msg_NE
 715            ("??variable& is not modified in loop body!", Ref, Var);
 716          Error_Msg_N
 717            ("\??possible infinite loop!", Ref);
 718       end if;
 719    end Check_Infinite_Loop_Warning;
 720 
 721    ----------------------------
 722    -- Check_Low_Bound_Tested --
 723    ----------------------------
 724 
 725    procedure Check_Low_Bound_Tested (Expr : Node_Id) is
 726       procedure Check_Low_Bound_Tested_For (Opnd : Node_Id);
 727       --  Determine whether operand Opnd denotes attribute 'First whose prefix
 728       --  is a formal parameter. If this is the case, mark the entity of the
 729       --  prefix as having its low bound tested.
 730 
 731       --------------------------------
 732       -- Check_Low_Bound_Tested_For --
 733       --------------------------------
 734 
 735       procedure Check_Low_Bound_Tested_For (Opnd : Node_Id) is
 736       begin
 737          if Nkind (Opnd) = N_Attribute_Reference
 738            and then Attribute_Name (Opnd) = Name_First
 739            and then Is_Entity_Name (Prefix (Opnd))
 740            and then Present (Entity (Prefix (Opnd)))
 741            and then Is_Formal (Entity (Prefix (Opnd)))
 742          then
 743             Set_Low_Bound_Tested (Entity (Prefix (Opnd)));
 744          end if;
 745       end Check_Low_Bound_Tested_For;
 746 
 747    --  Start of processing for Check_Low_Bound_Tested
 748 
 749    begin
 750       if Comes_From_Source (Expr) then
 751          Check_Low_Bound_Tested_For (Left_Opnd  (Expr));
 752          Check_Low_Bound_Tested_For (Right_Opnd (Expr));
 753       end if;
 754    end Check_Low_Bound_Tested;
 755 
 756    ----------------------
 757    -- Check_References --
 758    ----------------------
 759 
 760    procedure Check_References (E : Entity_Id; Anod : Node_Id := Empty) is
 761       E1  : Entity_Id;
 762       E1T : Entity_Id;
 763       UR  : Node_Id;
 764 
 765       function Body_Formal
 766         (E                : Entity_Id;
 767          Accept_Statement : Node_Id) return Entity_Id;
 768       --  For an entry formal entity from an entry declaration, find the
 769       --  corresponding body formal from the given accept statement.
 770 
 771       procedure May_Need_Initialized_Actual (Ent : Entity_Id);
 772       --  If an entity of a generic type has default initialization, then the
 773       --  corresponding actual type should be fully initialized, or else there
 774       --  will be uninitialized components in the instantiation, that might go
 775       --  unreported. This routine marks the type of the uninitialized variable
 776       --  appropriately to allow the compiler to emit an appropriate warning
 777       --  in the instance. In a sense, the use of a type that requires full
 778       --  initialization is a weak part of the generic contract.
 779 
 780       function Missing_Subunits return Boolean;
 781       --  We suppress warnings when there are missing subunits, because this
 782       --  may generate too many false positives: entities in a parent may only
 783       --  be referenced in one of the subunits. We make an exception for
 784       --  subunits that contain no other stubs.
 785 
 786       procedure Output_Reference_Error (M : String);
 787       --  Used to output an error message. Deals with posting the error on the
 788       --  body formal in the accept case.
 789 
 790       function Publicly_Referenceable (Ent : Entity_Id) return Boolean;
 791       --  This is true if the entity in question is potentially referenceable
 792       --  from another unit. This is true for entities in packages that are at
 793       --  the library level.
 794 
 795       function Warnings_Off_E1 return Boolean;
 796       --  Return True if Warnings_Off is set for E1, or for its Etype (E1T),
 797       --  or for the base type of E1T.
 798 
 799       -----------------
 800       -- Body_Formal --
 801       -----------------
 802 
 803       function Body_Formal
 804         (E                : Entity_Id;
 805          Accept_Statement : Node_Id) return Entity_Id
 806       is
 807          Body_Param : Node_Id;
 808          Body_E     : Entity_Id;
 809 
 810       begin
 811          --  Loop to find matching parameter in accept statement
 812 
 813          Body_Param := First (Parameter_Specifications (Accept_Statement));
 814          while Present (Body_Param) loop
 815             Body_E := Defining_Identifier (Body_Param);
 816 
 817             if Chars (Body_E) = Chars (E) then
 818                return Body_E;
 819             end if;
 820 
 821             Next (Body_Param);
 822          end loop;
 823 
 824          --  Should never fall through, should always find a match
 825 
 826          raise Program_Error;
 827       end Body_Formal;
 828 
 829       ---------------------------------
 830       -- May_Need_Initialized_Actual --
 831       ---------------------------------
 832 
 833       procedure May_Need_Initialized_Actual (Ent : Entity_Id) is
 834          T   : constant Entity_Id := Etype (Ent);
 835          Par : constant Node_Id   := Parent (T);
 836 
 837       begin
 838          if not Is_Generic_Type (T) then
 839             null;
 840 
 841          elsif (Nkind (Par)) = N_Private_Extension_Declaration then
 842 
 843             --  We only indicate the first such variable in the generic.
 844 
 845             if No (Uninitialized_Variable (Par)) then
 846                Set_Uninitialized_Variable (Par, Ent);
 847             end if;
 848 
 849          elsif (Nkind (Par)) = N_Formal_Type_Declaration
 850            and then Nkind (Formal_Type_Definition (Par)) =
 851                                          N_Formal_Private_Type_Definition
 852          then
 853             if No (Uninitialized_Variable (Formal_Type_Definition (Par))) then
 854                Set_Uninitialized_Variable (Formal_Type_Definition (Par), Ent);
 855             end if;
 856          end if;
 857       end May_Need_Initialized_Actual;
 858 
 859       ----------------------
 860       -- Missing_Subunits --
 861       ----------------------
 862 
 863       function Missing_Subunits return Boolean is
 864          D : Node_Id;
 865 
 866       begin
 867          if not Unloaded_Subunits then
 868 
 869             --  Normal compilation, all subunits are present
 870 
 871             return False;
 872 
 873          elsif E /= Main_Unit_Entity then
 874 
 875             --  No warnings on a stub that is not the main unit
 876 
 877             return True;
 878 
 879          elsif Nkind (Unit_Declaration_Node (E)) in N_Proper_Body then
 880             D := First (Declarations (Unit_Declaration_Node (E)));
 881             while Present (D) loop
 882 
 883                --  No warnings if the proper body contains nested stubs
 884 
 885                if Nkind (D) in N_Body_Stub then
 886                   return True;
 887                end if;
 888 
 889                Next (D);
 890             end loop;
 891 
 892             return False;
 893 
 894          else
 895             --  Missing stubs elsewhere
 896 
 897             return True;
 898          end if;
 899       end Missing_Subunits;
 900 
 901       ----------------------------
 902       -- Output_Reference_Error --
 903       ----------------------------
 904 
 905       procedure Output_Reference_Error (M : String) is
 906       begin
 907          --  Never issue messages for internal names or renamings
 908 
 909          if Is_Internal_Name (Chars (E1))
 910            or else Nkind (Parent (E1)) = N_Object_Renaming_Declaration
 911          then
 912             return;
 913          end if;
 914 
 915          --  Don't output message for IN OUT formal unless we have the warning
 916          --  flag specifically set. It is a bit odd to distinguish IN OUT
 917          --  formals from other cases. This distinction is historical in
 918          --  nature. Warnings for IN OUT formals were added fairly late.
 919 
 920          if Ekind (E1) = E_In_Out_Parameter
 921            and then not Check_Unreferenced_Formals
 922          then
 923             return;
 924          end if;
 925 
 926          --  Other than accept case, post error on defining identifier
 927 
 928          if No (Anod) then
 929             Error_Msg_N (M, E1);
 930 
 931          --  Accept case, find body formal to post the message
 932 
 933          else
 934             Error_Msg_NE (M, Body_Formal (E1, Accept_Statement => Anod), E1);
 935 
 936          end if;
 937       end Output_Reference_Error;
 938 
 939       ----------------------------
 940       -- Publicly_Referenceable --
 941       ----------------------------
 942 
 943       function Publicly_Referenceable (Ent : Entity_Id) return Boolean is
 944          P    : Node_Id;
 945          Prev : Node_Id;
 946 
 947       begin
 948          --  A formal parameter is never referenceable outside the body of its
 949          --  subprogram or entry.
 950 
 951          if Is_Formal (Ent) then
 952             return False;
 953          end if;
 954 
 955          --  Examine parents to look for a library level package spec. But if
 956          --  we find a body or block or other similar construct along the way,
 957          --  we cannot be referenced.
 958 
 959          Prev := Ent;
 960          P    := Parent (Ent);
 961          loop
 962             case Nkind (P) is
 963 
 964                --  If we get to top of tree, then publicly referenceable
 965 
 966                when N_Empty =>
 967                   return True;
 968 
 969                --  If we reach a generic package declaration, then always
 970                --  consider this referenceable, since any instantiation will
 971                --  have access to the entities in the generic package. Note
 972                --  that the package itself may not be instantiated, but then
 973                --  we will get a warning for the package entity.
 974 
 975                --  Note that generic formal parameters are themselves not
 976                --  publicly referenceable in an instance, and warnings on them
 977                --  are useful.
 978 
 979                when N_Generic_Package_Declaration =>
 980                   return
 981                     not Is_List_Member (Prev)
 982                       or else List_Containing (Prev) /=
 983                                             Generic_Formal_Declarations (P);
 984 
 985                --  Similarly, the generic formals of a generic subprogram are
 986                --  not accessible.
 987 
 988                when N_Generic_Subprogram_Declaration  =>
 989                   if Is_List_Member (Prev)
 990                     and then List_Containing (Prev) =
 991                                Generic_Formal_Declarations (P)
 992                   then
 993                      return False;
 994                   else
 995                      P := Parent (P);
 996                   end if;
 997 
 998                --  If we reach a subprogram body, entity is not referenceable
 999                --  unless it is the defining entity of the body. This will
1000                --  happen, e.g. when a function is an attribute renaming that
1001                --  is rewritten as a body.
1002 
1003                when N_Subprogram_Body  =>
1004                   if Ent /= Defining_Entity (P) then
1005                      return False;
1006                   else
1007                      P := Parent (P);
1008                   end if;
1009 
1010                --  If we reach any other body, definitely not referenceable
1011 
1012                when N_Package_Body    |
1013                     N_Task_Body       |
1014                     N_Entry_Body      |
1015                     N_Protected_Body  |
1016                     N_Block_Statement |
1017                     N_Subunit         =>
1018                   return False;
1019 
1020                --  For all other cases, keep looking up tree
1021 
1022                when others =>
1023                   Prev := P;
1024                   P    := Parent (P);
1025             end case;
1026          end loop;
1027       end Publicly_Referenceable;
1028 
1029       ---------------------
1030       -- Warnings_Off_E1 --
1031       ---------------------
1032 
1033       function Warnings_Off_E1 return Boolean is
1034       begin
1035          return Has_Warnings_Off (E1T)
1036            or else Has_Warnings_Off (Base_Type (E1T))
1037            or else Warnings_Off_Check_Spec (E1);
1038       end Warnings_Off_E1;
1039 
1040    --  Start of processing for Check_References
1041 
1042    begin
1043       Process_Deferred_References;
1044 
1045       --  No messages if warnings are suppressed, or if we have detected any
1046       --  real errors so far (this last check avoids junk messages resulting
1047       --  from errors, e.g. a subunit that is not loaded).
1048 
1049       if Warning_Mode = Suppress or else Serious_Errors_Detected /= 0 then
1050          return;
1051       end if;
1052 
1053       --  We also skip the messages if any subunits were not loaded (see
1054       --  comment in Sem_Ch10 to understand how this is set, and why it is
1055       --  necessary to suppress the warnings in this case).
1056 
1057       if Missing_Subunits then
1058          return;
1059       end if;
1060 
1061       --  Otherwise loop through entities, looking for suspicious stuff
1062 
1063       E1 := First_Entity (E);
1064       while Present (E1) loop
1065          E1T := Etype (E1);
1066 
1067          --  We are only interested in source entities. We also don't issue
1068          --  warnings within instances, since the proper place for such
1069          --  warnings is on the template when it is compiled, and we don't
1070          --  issue warnings for variables with names like Junk, Discard etc.
1071 
1072          if Comes_From_Source (E1)
1073            and then Instantiation_Location (Sloc (E1)) = No_Location
1074          then
1075             --  We are interested in variables and out/in-out parameters, but
1076             --  we exclude protected types, too complicated to worry about.
1077 
1078             if Ekind (E1) = E_Variable
1079               or else
1080                 (Ekind_In (E1, E_Out_Parameter, E_In_Out_Parameter)
1081                   and then not Is_Protected_Type (Current_Scope))
1082             then
1083                --  If the formal has a class-wide type, retrieve its type
1084                --  because checks below depend on its private nature.
1085 
1086                if Is_Class_Wide_Type (E1T) then
1087                   E1T := Etype (E1T);
1088                end if;
1089 
1090                --  Case of an unassigned variable
1091 
1092                --  First gather any Unset_Reference indication for E1. In the
1093                --  case of a parameter, it is the Spec_Entity that is relevant.
1094 
1095                if Ekind (E1) = E_Out_Parameter
1096                  and then Present (Spec_Entity (E1))
1097                then
1098                   UR := Unset_Reference (Spec_Entity (E1));
1099                else
1100                   UR := Unset_Reference (E1);
1101                end if;
1102 
1103                --  Special processing for access types
1104 
1105                if Present (UR) and then Is_Access_Type (E1T) then
1106 
1107                   --  For access types, the only time we made a UR entry was
1108                   --  for a dereference, and so we post the appropriate warning
1109                   --  here (note that the dereference may not be explicit in
1110                   --  the source, for example in the case of a dispatching call
1111                   --  with an anonymous access controlling formal, or of an
1112                   --  assignment of a pointer involving discriminant check on
1113                   --  the designated object).
1114 
1115                   if not Warnings_Off_E1 then
1116                      Error_Msg_NE ("??& may be null!", UR, E1);
1117                   end if;
1118 
1119                   goto Continue;
1120 
1121                --  Case of variable that could be a constant. Note that we
1122                --  never signal such messages for generic package entities,
1123                --  since a given instance could have modifications outside
1124                --  the package.
1125 
1126                --  Note that we used to check Address_Taken here, but we don't
1127                --  want to do that since it can be set for non-source cases,
1128                --  e.g. the Unrestricted_Access from a valid attribute, and
1129                --  the wanted effect is included in Never_Set_In_Source.
1130 
1131                elsif Warn_On_Constant
1132                  and then (Ekind (E1) = E_Variable
1133                             and then Has_Initial_Value (E1))
1134                  and then Never_Set_In_Source_Check_Spec (E1)
1135                  and then not Generic_Package_Spec_Entity (E1)
1136                then
1137                   --  A special case, if this variable is volatile and not
1138                   --  imported, it is not helpful to tell the programmer
1139                   --  to mark the variable as constant, since this would be
1140                   --  illegal by virtue of RM C.6(13). Instead we suggest
1141                   --  using pragma Export (can't be Import because of the
1142                   --  initial value).
1143 
1144                   if (Is_Volatile (E1) or else Has_Volatile_Components (E1))
1145                     and then not Is_Imported (E1)
1146                   then
1147                      Error_Msg_N
1148                        ("?k?& is not modified, consider pragma Export for "
1149                         & "volatile variable!", E1);
1150 
1151                   --  Another special case, Exception_Occurrence, this catches
1152                   --  the case of exception choice (and a bit more too, but not
1153                   --  worth doing more investigation here).
1154 
1155                   elsif Is_RTE (E1T, RE_Exception_Occurrence) then
1156                      null;
1157 
1158                   --  Here we give the warning if referenced and no pragma
1159                   --  Unreferenced or Unmodified is present.
1160 
1161                   else
1162                      --  Variable case
1163 
1164                      if Ekind (E1) = E_Variable then
1165                         if Referenced_Check_Spec (E1)
1166                           and then not Has_Pragma_Unreferenced_Check_Spec (E1)
1167                           and then not Has_Pragma_Unmodified_Check_Spec (E1)
1168                         then
1169                            if not Warnings_Off_E1
1170                              and then not Has_Junk_Name (E1)
1171                            then
1172                               Error_Msg_N -- CODEFIX
1173                                 ("?k?& is not modified, "
1174                                  & "could be declared constant!",
1175                                  E1);
1176                            end if;
1177                         end if;
1178                      end if;
1179                   end if;
1180 
1181                --  Other cases of a variable or parameter never set in source
1182 
1183                elsif Never_Set_In_Source_Check_Spec (E1)
1184 
1185                  --  No warning if warning for this case turned off
1186 
1187                  and then Warn_On_No_Value_Assigned
1188 
1189                  --  No warning if address taken somewhere
1190 
1191                  and then not Address_Taken (E1)
1192 
1193                  --  No warning if explicit initial value
1194 
1195                  and then not Has_Initial_Value (E1)
1196 
1197                  --  No warning for generic package spec entities, since we
1198                  --  might set them in a child unit or something like that
1199 
1200                  and then not Generic_Package_Spec_Entity (E1)
1201 
1202                  --  No warning if fully initialized type, except that for
1203                  --  this purpose we do not consider access types to qualify
1204                  --  as fully initialized types (relying on an access type
1205                  --  variable being null when it is never set is a bit odd).
1206 
1207                  --  Also we generate warning for an out parameter that is
1208                  --  never referenced, since again it seems odd to rely on
1209                  --  default initialization to set an out parameter value.
1210 
1211                 and then (Is_Access_Type (E1T)
1212                            or else Ekind (E1) = E_Out_Parameter
1213                            or else not Is_Fully_Initialized_Type (E1T))
1214                then
1215                   --  Do not output complaint about never being assigned a
1216                   --  value if a pragma Unmodified applies to the variable
1217                   --  we are examining, or if it is a parameter, if there is
1218                   --  a pragma Unreferenced for the corresponding spec, or
1219                   --  if the type is marked as having unreferenced objects.
1220                   --  The last is a little peculiar, but better too few than
1221                   --  too many warnings in this situation.
1222 
1223                   if Has_Pragma_Unreferenced_Objects (E1T)
1224                     or else Has_Pragma_Unmodified_Check_Spec (E1)
1225                   then
1226                      null;
1227 
1228                   --  IN OUT parameter case where parameter is referenced. We
1229                   --  separate this out, since this is the case where we delay
1230                   --  output of the warning until more information is available
1231                   --  (about use in an instantiation or address being taken).
1232 
1233                   elsif Ekind (E1) = E_In_Out_Parameter
1234                     and then Referenced_Check_Spec (E1)
1235                   then
1236                      --  Suppress warning if private type, and the procedure
1237                      --  has a separate declaration in a different unit. This
1238                      --  is the case where the client of a package sees only
1239                      --  the private type, and it may be quite reasonable
1240                      --  for the logical view to be IN OUT, even if the
1241                      --  implementation ends up using access types or some
1242                      --  other method to achieve the local effect of a
1243                      --  modification. On the other hand if the spec and body
1244                      --  are in the same unit, we are in the package body and
1245                      --  there we have less excuse for a junk IN OUT parameter.
1246 
1247                      if Has_Private_Declaration (E1T)
1248                        and then Present (Spec_Entity (E1))
1249                        and then not In_Same_Source_Unit (E1, Spec_Entity (E1))
1250                      then
1251                         null;
1252 
1253                      --  Suppress warning for any parameter of a dispatching
1254                      --  operation, since it is quite reasonable to have an
1255                      --  operation that is overridden, and for some subclasses
1256                      --  needs the formal to be IN OUT and for others happens
1257                      --  not to assign it.
1258 
1259                      elsif Is_Dispatching_Operation
1260                              (Scope (Goto_Spec_Entity (E1)))
1261                      then
1262                         null;
1263 
1264                      --  Suppress warning if composite type contains any access
1265                      --  component, since the logical effect of modifying a
1266                      --  parameter may be achieved by modifying a referenced
1267                      --  object.
1268 
1269                      elsif Is_Composite_Type (E1T)
1270                        and then Has_Access_Values (E1T)
1271                      then
1272                         null;
1273 
1274                      --  Suppress warning on formals of an entry body. All
1275                      --  references are attached to the formal in the entry
1276                      --  declaration, which are marked Is_Entry_Formal.
1277 
1278                      elsif Ekind (Scope (E1)) = E_Entry
1279                        and then not Is_Entry_Formal (E1)
1280                      then
1281                         null;
1282 
1283                      --  OK, looks like warning for an IN OUT parameter that
1284                      --  could be IN makes sense, but we delay the output of
1285                      --  the warning, pending possibly finding out later on
1286                      --  that the associated subprogram is used as a generic
1287                      --  actual, or its address/access is taken. In these two
1288                      --  cases, we suppress the warning because the context may
1289                      --  force use of IN OUT, even if in this particular case
1290                      --  the formal is not modified.
1291 
1292                      else
1293                         --  Suppress the warnings for a junk name
1294 
1295                         if not Has_Junk_Name (E1) then
1296                            In_Out_Warnings.Append (E1);
1297                         end if;
1298                      end if;
1299 
1300                   --  Other cases of formals
1301 
1302                   elsif Is_Formal (E1) then
1303                      if not Is_Trivial_Subprogram (Scope (E1)) then
1304                         if Referenced_Check_Spec (E1) then
1305                            if not Has_Pragma_Unmodified_Check_Spec (E1)
1306                              and then not Warnings_Off_E1
1307                              and then not Has_Junk_Name (E1)
1308                            then
1309                               Output_Reference_Error
1310                                 ("?f?formal parameter& is read but "
1311                                  & "never assigned!");
1312                            end if;
1313 
1314                         elsif not Has_Pragma_Unreferenced_Check_Spec (E1)
1315                           and then not Warnings_Off_E1
1316                           and then not Has_Junk_Name (E1)
1317                         then
1318                            Output_Reference_Error
1319                              ("?f?formal parameter& is not referenced!");
1320                         end if;
1321                      end if;
1322 
1323                   --  Case of variable
1324 
1325                   else
1326                      if Referenced (E1) then
1327                         if not Has_Unmodified (E1)
1328                           and then not Warnings_Off_E1
1329                           and then not Has_Junk_Name (E1)
1330                         then
1331                            Output_Reference_Error
1332                              ("?v?variable& is read but never assigned!");
1333                            May_Need_Initialized_Actual (E1);
1334                         end if;
1335 
1336                      elsif not Has_Unreferenced (E1)
1337                        and then not Warnings_Off_E1
1338                        and then not Has_Junk_Name (E1)
1339                      then
1340                         Output_Reference_Error -- CODEFIX
1341                           ("?v?variable& is never read and never assigned!");
1342                      end if;
1343 
1344                      --  Deal with special case where this variable is hidden
1345                      --  by a loop variable.
1346 
1347                      if Ekind (E1) = E_Variable
1348                        and then Present (Hiding_Loop_Variable (E1))
1349                        and then not Warnings_Off_E1
1350                      then
1351                         Error_Msg_N
1352                           ("?v?for loop implicitly declares loop variable!",
1353                            Hiding_Loop_Variable (E1));
1354 
1355                         Error_Msg_Sloc := Sloc (E1);
1356                         Error_Msg_N
1357                           ("\?v?declaration hides & declared#!",
1358                            Hiding_Loop_Variable (E1));
1359                      end if;
1360                   end if;
1361 
1362                   goto Continue;
1363                end if;
1364 
1365                --  Check for unset reference
1366 
1367                if Warn_On_No_Value_Assigned and then Present (UR) then
1368 
1369                   --  For other than access type, go back to original node to
1370                   --  deal with case where original unset reference has been
1371                   --  rewritten during expansion.
1372 
1373                   --  In some cases, the original node may be a type conversion
1374                   --  or qualification, and in this case we want the object
1375                   --  entity inside.
1376 
1377                   UR := Original_Node (UR);
1378                   while Nkind (UR) = N_Type_Conversion
1379                     or else Nkind (UR) = N_Qualified_Expression
1380                     or else Nkind (UR) = N_Expression_With_Actions
1381                   loop
1382                      UR := Expression (UR);
1383                   end loop;
1384 
1385                   --  Don't issue warning if appearing inside Initial_Condition
1386                   --  pragma or aspect, since that expression is not evaluated
1387                   --  at the point where it occurs in the source.
1388 
1389                   if In_Pragma_Expression (UR, Name_Initial_Condition) then
1390                      goto Continue;
1391                   end if;
1392 
1393                   --  Here we issue the warning, all checks completed
1394 
1395                   --  If we have a return statement, this was a case of an OUT
1396                   --  parameter not being set at the time of the return. (Note:
1397                   --  it can't be N_Extended_Return_Statement, because those
1398                   --  are only for functions, and functions do not allow OUT
1399                   --  parameters.)
1400 
1401                   if not Is_Trivial_Subprogram (Scope (E1)) then
1402                      if Nkind (UR) = N_Simple_Return_Statement
1403                        and then not Has_Pragma_Unmodified_Check_Spec (E1)
1404                      then
1405                         if not Warnings_Off_E1
1406                           and then not Has_Junk_Name (E1)
1407                         then
1408                            Error_Msg_NE
1409                              ("?v?OUT parameter& not set before return",
1410                               UR, E1);
1411                         end if;
1412 
1413                         --  If the unset reference is a selected component
1414                         --  prefix from source, mention the component as well.
1415                         --  If the selected component comes from expansion, all
1416                         --  we know is that the entity is not fully initialized
1417                         --  at the point of the reference. Locate a random
1418                         --  uninitialized component to get a better message.
1419 
1420                      elsif Nkind (Parent (UR)) = N_Selected_Component then
1421                         Error_Msg_Node_2 := Selector_Name (Parent (UR));
1422 
1423                         if not Comes_From_Source (Parent (UR)) then
1424                            declare
1425                               Comp : Entity_Id;
1426 
1427                            begin
1428                               Comp := First_Entity (E1T);
1429                               while Present (Comp) loop
1430                                  if Ekind (Comp) = E_Component
1431                                    and then Nkind (Parent (Comp)) =
1432                                               N_Component_Declaration
1433                                    and then No (Expression (Parent (Comp)))
1434                                  then
1435                                     Error_Msg_Node_2 := Comp;
1436                                     exit;
1437                                  end if;
1438 
1439                                  Next_Entity (Comp);
1440                               end loop;
1441                            end;
1442                         end if;
1443 
1444                         --  Issue proper warning. This is a case of referencing
1445                         --  a variable before it has been explicitly assigned.
1446                         --  For access types, UR was only set for dereferences,
1447                         --  so the issue is that the value may be null.
1448 
1449                         if not Is_Trivial_Subprogram (Scope (E1)) then
1450                            if not Warnings_Off_E1 then
1451                               if Is_Access_Type (Etype (Parent (UR))) then
1452                                  Error_Msg_N ("??`&.&` may be null!", UR);
1453                               else
1454                                  Error_Msg_N
1455                                    ("??`&.&` may be referenced before "
1456                                     & "it has a value!", UR);
1457                               end if;
1458                            end if;
1459                         end if;
1460 
1461                      --  All other cases of unset reference active
1462 
1463                      elsif not Warnings_Off_E1 then
1464                         Error_Msg_N
1465                           ("??& may be referenced before it has a value!", UR);
1466                      end if;
1467                   end if;
1468 
1469                   goto Continue;
1470 
1471                end if;
1472             end if;
1473 
1474             --  Then check for unreferenced entities. Note that we are only
1475             --  interested in entities whose Referenced flag is not set.
1476 
1477             if not Referenced_Check_Spec (E1)
1478 
1479               --  If Referenced_As_LHS is set, then that's still interesting
1480               --  (potential "assigned but never read" case), but not if we
1481               --  have pragma Unreferenced, which cancels this warning.
1482 
1483               and then (not Referenced_As_LHS_Check_Spec (E1)
1484                          or else not Has_Unreferenced (E1))
1485 
1486               --  Check that warnings on unreferenced entities are enabled
1487 
1488               and then
1489                 ((Check_Unreferenced and then not Is_Formal (E1))
1490 
1491                   --  Case of warning on unreferenced formal
1492 
1493                   or else (Check_Unreferenced_Formals and then Is_Formal (E1))
1494 
1495                   --  Case of warning on unread variables modified by an
1496                   --  assignment, or an OUT parameter if it is the only one.
1497 
1498                   or else (Warn_On_Modified_Unread
1499                             and then Referenced_As_LHS_Check_Spec (E1))
1500 
1501                   --  Case of warning on any unread OUT parameter (note such
1502                   --  indications are only set if the appropriate warning
1503                   --  options were set, so no need to recheck here.)
1504 
1505                   or else Referenced_As_Out_Parameter_Check_Spec (E1))
1506 
1507               --  All other entities, including local packages that cannot be
1508               --  referenced from elsewhere, including those declared within a
1509               --  package body.
1510 
1511               and then (Is_Object (E1)
1512                          or else Is_Type (E1)
1513                          or else Ekind (E1) = E_Label
1514                          or else Ekind_In (E1, E_Exception,
1515                                                E_Named_Integer,
1516                                                E_Named_Real)
1517                          or else Is_Overloadable (E1)
1518 
1519                          --  Package case, if the main unit is a package spec
1520                          --  or generic package spec, then there may be a
1521                          --  corresponding body that references this package
1522                          --  in some other file. Otherwise we can be sure
1523                          --  that there is no other reference.
1524 
1525                          or else
1526                            (Ekind (E1) = E_Package
1527                              and then
1528                                not Is_Package_Or_Generic_Package
1529                                      (Cunit_Entity (Current_Sem_Unit))))
1530 
1531               --  Exclude instantiations, since there is no reason why every
1532               --  entity in an instantiation should be referenced.
1533 
1534               and then Instantiation_Location (Sloc (E1)) = No_Location
1535 
1536               --  Exclude formal parameters from bodies if the corresponding
1537               --  spec entity has been referenced in the case where there is
1538               --  a separate spec.
1539 
1540               and then not (Is_Formal (E1)
1541                              and then Ekind (Scope (E1)) = E_Subprogram_Body
1542                              and then Present (Spec_Entity (E1))
1543                              and then Referenced (Spec_Entity (E1)))
1544 
1545               --  Consider private type referenced if full view is referenced.
1546               --  If there is not full view, this is a generic type on which
1547               --  warnings are also useful.
1548 
1549               and then
1550                 not (Is_Private_Type (E1)
1551                       and then Present (Full_View (E1))
1552                       and then Referenced (Full_View (E1)))
1553 
1554               --  Don't worry about full view, only about private type
1555 
1556               and then not Has_Private_Declaration (E1)
1557 
1558               --  Eliminate dispatching operations from consideration, we
1559               --  cannot tell if these are referenced or not in any easy
1560               --  manner (note this also catches Adjust/Finalize/Initialize).
1561 
1562               and then not Is_Dispatching_Operation (E1)
1563 
1564               --  Check entity that can be publicly referenced (we do not give
1565               --  messages for such entities, since there could be other
1566               --  units, not involved in this compilation, that contain
1567               --  relevant references.
1568 
1569               and then not Publicly_Referenceable (E1)
1570 
1571               --  Class wide types are marked as source entities, but they are
1572               --  not really source entities, and are always created, so we do
1573               --  not care if they are not referenced.
1574 
1575               and then Ekind (E1) /= E_Class_Wide_Type
1576 
1577               --  Objects other than parameters of task types are allowed to
1578               --  be non-referenced, since they start up tasks.
1579 
1580               and then ((Ekind (E1) /= E_Variable
1581                           and then Ekind (E1) /= E_Constant
1582                           and then Ekind (E1) /= E_Component)
1583                          or else not Is_Task_Type (E1T))
1584 
1585               --  For subunits, only place warnings on the main unit itself,
1586               --  since parent units are not completely compiled.
1587 
1588               and then (Nkind (Unit (Cunit (Main_Unit))) /= N_Subunit
1589                          or else Get_Source_Unit (E1) = Main_Unit)
1590 
1591               --  No warning on a return object, because these are often
1592               --  created with a single expression and an implicit return.
1593               --  If the object is a variable there will be a warning
1594               --  indicating that it could be declared constant.
1595 
1596               and then not
1597                 (Ekind (E1) = E_Constant and then Is_Return_Object (E1))
1598             then
1599                --  Suppress warnings in internal units if not in -gnatg mode
1600                --  (these would be junk warnings for an applications program,
1601                --  since they refer to problems in internal units).
1602 
1603                if GNAT_Mode
1604                  or else not Is_Internal_File_Name
1605                                (Unit_File_Name (Get_Source_Unit (E1)))
1606                then
1607                   --  We do not immediately flag the error. This is because we
1608                   --  have not expanded generic bodies yet, and they may have
1609                   --  the missing reference. So instead we park the entity on a
1610                   --  list, for later processing. However for the case of an
1611                   --  accept statement we want to output messages now, since
1612                   --  we know we already have all information at hand, and we
1613                   --  also want to have separate warnings for each accept
1614                   --  statement for the same entry.
1615 
1616                   if Present (Anod) then
1617                      pragma Assert (Is_Formal (E1));
1618 
1619                      --  The unreferenced entity is E1, but post the warning
1620                      --  on the body entity for this accept statement.
1621 
1622                      if not Warnings_Off_E1 then
1623                         Warn_On_Unreferenced_Entity
1624                           (E1, Body_Formal (E1, Accept_Statement => Anod));
1625                      end if;
1626 
1627                   elsif not Warnings_Off_E1
1628                     and then not Has_Junk_Name (E1)
1629                   then
1630                      Unreferenced_Entities.Append (E1);
1631                   end if;
1632                end if;
1633 
1634             --  Generic units are referenced in the generic body, but if they
1635             --  are not public and never instantiated we want to force a
1636             --  warning on them. We treat them as redundant constructs to
1637             --  minimize noise.
1638 
1639             elsif Is_Generic_Subprogram (E1)
1640               and then not Is_Instantiated (E1)
1641               and then not Publicly_Referenceable (E1)
1642               and then Instantiation_Depth (Sloc (E1)) = 0
1643               and then Warn_On_Redundant_Constructs
1644             then
1645                if not Warnings_Off_E1 and then not Has_Junk_Name (E1) then
1646                   Unreferenced_Entities.Append (E1);
1647 
1648                   --  Force warning on entity
1649 
1650                   Set_Referenced (E1, False);
1651                end if;
1652             end if;
1653          end if;
1654 
1655          --  Recurse into nested package or block. Do not recurse into a formal
1656          --  package, because the corresponding body is not analyzed.
1657 
1658          <<Continue>>
1659             if (Is_Package_Or_Generic_Package (E1)
1660                  and then Nkind (Parent (E1)) = N_Package_Specification
1661                  and then
1662                    Nkind (Original_Node (Unit_Declaration_Node (E1))) /=
1663                                                 N_Formal_Package_Declaration)
1664 
1665               or else Ekind (E1) = E_Block
1666             then
1667                Check_References (E1);
1668             end if;
1669 
1670             Next_Entity (E1);
1671       end loop;
1672    end Check_References;
1673 
1674    ---------------------------
1675    -- Check_Unset_Reference --
1676    ---------------------------
1677 
1678    procedure Check_Unset_Reference (N : Node_Id) is
1679       Typ : constant Entity_Id := Etype (N);
1680 
1681       function Is_OK_Fully_Initialized return Boolean;
1682       --  This function returns true if the given node N is fully initialized
1683       --  so that the reference is safe as far as this routine is concerned.
1684       --  Safe generally means that the type of N is a fully initialized type.
1685       --  The one special case is that for access types, which are always fully
1686       --  initialized, we don't consider a dereference OK since it will surely
1687       --  be dereferencing a null value, which won't do.
1688 
1689       function Prefix_Has_Dereference (Pref : Node_Id) return Boolean;
1690       --  Used to test indexed or selected component or slice to see if the
1691       --  evaluation of the prefix depends on a dereference, and if so, returns
1692       --  True, in which case we always check the prefix, even if we know that
1693       --  the referenced component is initialized. Pref is the prefix to test.
1694 
1695       -----------------------------
1696       -- Is_OK_Fully_Initialized --
1697       -----------------------------
1698 
1699       function Is_OK_Fully_Initialized return Boolean is
1700       begin
1701          if Is_Access_Type (Typ) and then Is_Dereferenced (N) then
1702             return False;
1703 
1704          --  If a type has Default_Initial_Condition set, or it inherits it,
1705          --  DIC might be specified with a boolean value, meaning that the type
1706          --  is considered to be fully default initialized (SPARK RM 3.1 and
1707          --  SPARK RM 7.3.3). To avoid generating spurious warnings in this
1708          --  case, consider all types with DIC as fully initialized.
1709 
1710          elsif Has_Default_Init_Cond (Typ)
1711            or else Has_Inherited_Default_Init_Cond (Typ)
1712          then
1713             return True;
1714 
1715          else
1716             return Is_Fully_Initialized_Type (Typ);
1717          end if;
1718       end Is_OK_Fully_Initialized;
1719 
1720       ----------------------------
1721       -- Prefix_Has_Dereference --
1722       ----------------------------
1723 
1724       function Prefix_Has_Dereference (Pref : Node_Id) return Boolean is
1725       begin
1726          --  If prefix is of an access type, it certainly needs a dereference
1727 
1728          if Is_Access_Type (Etype (Pref)) then
1729             return True;
1730 
1731          --  If prefix is explicit dereference, that's a dereference for sure
1732 
1733          elsif Nkind (Pref) = N_Explicit_Dereference then
1734             return True;
1735 
1736             --  If prefix is itself a component reference or slice check prefix
1737 
1738          elsif Nkind (Pref) = N_Slice
1739            or else Nkind (Pref) = N_Indexed_Component
1740            or else Nkind (Pref) = N_Selected_Component
1741          then
1742             return Prefix_Has_Dereference (Prefix (Pref));
1743 
1744          --  All other cases do not involve a dereference
1745 
1746          else
1747             return False;
1748          end if;
1749       end Prefix_Has_Dereference;
1750 
1751    --  Start of processing for Check_Unset_Reference
1752 
1753    begin
1754       --  Nothing to do if warnings suppressed
1755 
1756       if Warning_Mode = Suppress then
1757          return;
1758       end if;
1759 
1760       --  Nothing to do for numeric or string literal. Do this test early to
1761       --  save time in a common case (it does not matter that we do not include
1762       --  character literal here, since that will be caught later on in the
1763       --  when others branch of the case statement).
1764 
1765       if Nkind (N) in N_Numeric_Or_String_Literal then
1766          return;
1767       end if;
1768 
1769       --  Ignore reference unless it comes from source. Almost always if we
1770       --  have a reference from generated code, it is bogus (e.g. calls to init
1771       --  procs to set default discriminant values).
1772 
1773       if not Comes_From_Source (N) then
1774          return;
1775       end if;
1776 
1777       --  Otherwise see what kind of node we have. If the entity already has an
1778       --  unset reference, it is not necessarily the earliest in the text,
1779       --  because resolution of the prefix of selected components is completed
1780       --  before the resolution of the selected component itself. As a result,
1781       --  given (R /= null and then R.X > 0), the occurrences of R are examined
1782       --  in right-to-left order. If there is already an unset reference, we
1783       --  check whether N is earlier before proceeding.
1784 
1785       case Nkind (N) is
1786 
1787          --  For identifier or expanded name, examine the entity involved
1788 
1789          when N_Identifier | N_Expanded_Name =>
1790             declare
1791                E : constant Entity_Id := Entity (N);
1792 
1793             begin
1794                if Ekind_In (E, E_Variable, E_Out_Parameter)
1795                  and then Never_Set_In_Source_Check_Spec (E)
1796                  and then not Has_Initial_Value (E)
1797                  and then (No (Unset_Reference (E))
1798                             or else
1799                               Earlier_In_Extended_Unit
1800                                 (Sloc (N), Sloc (Unset_Reference (E))))
1801                  and then not Has_Pragma_Unmodified_Check_Spec (E)
1802                  and then not Warnings_Off_Check_Spec (E)
1803                  and then not Has_Junk_Name (E)
1804                then
1805                   --  We may have an unset reference. The first test is whether
1806                   --  this is an access to a discriminant of a record or a
1807                   --  component with default initialization. Both of these
1808                   --  cases can be ignored, since the actual object that is
1809                   --  referenced is definitely initialized. Note that this
1810                   --  covers the case of reading discriminants of an OUT
1811                   --  parameter, which is OK even in Ada 83.
1812 
1813                   --  Note that we are only interested in a direct reference to
1814                   --  a record component here. If the reference is through an
1815                   --  access type, then the access object is being referenced,
1816                   --  not the record, and still deserves an unset reference.
1817 
1818                   if Nkind (Parent (N)) = N_Selected_Component
1819                     and not Is_Access_Type (Typ)
1820                   then
1821                      declare
1822                         ES : constant Entity_Id :=
1823                                Entity (Selector_Name (Parent (N)));
1824                      begin
1825                         if Ekind (ES) = E_Discriminant
1826                           or else
1827                             (Present (Declaration_Node (ES))
1828                                and then
1829                              Present (Expression (Declaration_Node (ES))))
1830                         then
1831                            return;
1832                         end if;
1833                      end;
1834                   end if;
1835 
1836                   --  Exclude fully initialized types
1837 
1838                   if Is_OK_Fully_Initialized then
1839                      return;
1840                   end if;
1841 
1842                   --  Here we have a potential unset reference. But before we
1843                   --  get worried about it, we have to make sure that the
1844                   --  entity declaration is in the same procedure as the
1845                   --  reference, since if they are in separate procedures, then
1846                   --  we have no idea about sequential execution.
1847 
1848                   --  The tests in the loop below catch all such cases, but do
1849                   --  allow the reference to appear in a loop, block, or
1850                   --  package spec that is nested within the declaring scope.
1851                   --  As always, it is possible to construct cases where the
1852                   --  warning is wrong, that is why it is a warning.
1853 
1854                   Potential_Unset_Reference : declare
1855                      SR : Entity_Id;
1856                      SE : constant Entity_Id := Scope (E);
1857 
1858                      function Within_Postcondition return Boolean;
1859                      --  Returns True if N is within a Postcondition, a
1860                      --  Refined_Post, an Ensures component in a Test_Case,
1861                      --  or a Contract_Cases.
1862 
1863                      --------------------------
1864                      -- Within_Postcondition --
1865                      --------------------------
1866 
1867                      function Within_Postcondition return Boolean is
1868                         Nod, P : Node_Id;
1869 
1870                      begin
1871                         Nod := Parent (N);
1872                         while Present (Nod) loop
1873                            if Nkind (Nod) = N_Pragma
1874                              and then Nam_In (Pragma_Name (Nod),
1875                                               Name_Postcondition,
1876                                               Name_Refined_Post,
1877                                               Name_Contract_Cases)
1878                            then
1879                               return True;
1880 
1881                            elsif Present (Parent (Nod)) then
1882                               P := Parent (Nod);
1883 
1884                               if Nkind (P) = N_Pragma
1885                                 and then Pragma_Name (P) = Name_Test_Case
1886                                 and then Nod = Test_Case_Arg (P, Name_Ensures)
1887                               then
1888                                  return True;
1889                               end if;
1890                            end if;
1891 
1892                            Nod := Parent (Nod);
1893                         end loop;
1894 
1895                         return False;
1896                      end Within_Postcondition;
1897 
1898                   --  Start of processing for Potential_Unset_Reference
1899 
1900                   begin
1901                      SR := Current_Scope;
1902                      while SR /= SE loop
1903                         if SR = Standard_Standard
1904                           or else Is_Subprogram (SR)
1905                           or else Is_Concurrent_Body (SR)
1906                           or else Is_Concurrent_Type (SR)
1907                         then
1908                            return;
1909                         end if;
1910 
1911                         SR := Scope (SR);
1912                      end loop;
1913 
1914                      --  Case of reference has an access type. This is a
1915                      --  special case since access types are always set to null
1916                      --  so cannot be truly uninitialized, but we still want to
1917                      --  warn about cases of obvious null dereference.
1918 
1919                      if Is_Access_Type (Typ) then
1920                         Access_Type_Case : declare
1921                            P : Node_Id;
1922 
1923                            function Process
1924                              (N : Node_Id) return Traverse_Result;
1925                            --  Process function for instantiation of Traverse
1926                            --  below. Checks if N contains reference to E other
1927                            --  than a dereference.
1928 
1929                            function Ref_In (Nod : Node_Id) return Boolean;
1930                            --  Determines whether Nod contains a reference to
1931                            --  the entity E that is not a dereference.
1932 
1933                            -------------
1934                            -- Process --
1935                            -------------
1936 
1937                            function Process
1938                              (N : Node_Id) return Traverse_Result
1939                            is
1940                            begin
1941                               if Is_Entity_Name (N)
1942                                 and then Entity (N) = E
1943                                 and then not Is_Dereferenced (N)
1944                               then
1945                                  return Abandon;
1946                               else
1947                                  return OK;
1948                               end if;
1949                            end Process;
1950 
1951                            ------------
1952                            -- Ref_In --
1953                            ------------
1954 
1955                            function Ref_In (Nod : Node_Id) return Boolean is
1956                               function Traverse is new Traverse_Func (Process);
1957                            begin
1958                               return Traverse (Nod) = Abandon;
1959                            end Ref_In;
1960 
1961                         --  Start of processing for Access_Type_Case
1962 
1963                         begin
1964                            --  Don't bother if we are inside an instance, since
1965                            --  the compilation of the generic template is where
1966                            --  the warning should be issued.
1967 
1968                            if In_Instance then
1969                               return;
1970                            end if;
1971 
1972                            --  Don't bother if this is not the main unit. If we
1973                            --  try to give this warning for with'ed units, we
1974                            --  get some false positives, since we do not record
1975                            --  references in other units.
1976 
1977                            if not In_Extended_Main_Source_Unit (E)
1978                                 or else
1979                               not In_Extended_Main_Source_Unit (N)
1980                            then
1981                               return;
1982                            end if;
1983 
1984                            --  We are only interested in dereferences
1985 
1986                            if not Is_Dereferenced (N) then
1987                               return;
1988                            end if;
1989 
1990                            --  One more check, don't bother with references
1991                            --  that are inside conditional statements or WHILE
1992                            --  loops if the condition references the entity in
1993                            --  question. This avoids most false positives.
1994 
1995                            P := Parent (N);
1996                            loop
1997                               P := Parent (P);
1998                               exit when No (P);
1999 
2000                               if Nkind_In (P, N_If_Statement, N_Elsif_Part)
2001                                 and then Ref_In (Condition (P))
2002                               then
2003                                  return;
2004 
2005                               elsif Nkind (P) = N_Loop_Statement
2006                                 and then Present (Iteration_Scheme (P))
2007                                 and then
2008                                   Ref_In (Condition (Iteration_Scheme (P)))
2009                               then
2010                                  return;
2011                               end if;
2012                            end loop;
2013                         end Access_Type_Case;
2014                      end if;
2015 
2016                      --  One more check, don't bother if we are within a
2017                      --  postcondition, since the expression occurs in a
2018                      --  place unrelated to the actual test.
2019 
2020                      if not Within_Postcondition then
2021 
2022                         --  Here we definitely have a case for giving a warning
2023                         --  for a reference to an unset value. But we don't
2024                         --  give the warning now. Instead set Unset_Reference
2025                         --  in the identifier involved. The reason for this is
2026                         --  that if we find the variable is never ever assigned
2027                         --  a value then that warning is more important and
2028                         --  there is no point in giving the reference warning.
2029 
2030                         --  If this is an identifier, set the field directly
2031 
2032                         if Nkind (N) = N_Identifier then
2033                            Set_Unset_Reference (E, N);
2034 
2035                         --  Otherwise it is an expanded name, so set the field
2036                         --  of the actual identifier for the reference.
2037 
2038                         else
2039                            Set_Unset_Reference (E, Selector_Name (N));
2040                         end if;
2041                      end if;
2042                   end Potential_Unset_Reference;
2043                end if;
2044             end;
2045 
2046          --  Indexed component or slice
2047 
2048          when N_Indexed_Component | N_Slice =>
2049 
2050             --  If prefix does not involve dereferencing an access type, then
2051             --  we know we are OK if the component type is fully initialized,
2052             --  since the component will have been set as part of the default
2053             --  initialization.
2054 
2055             if not Prefix_Has_Dereference (Prefix (N))
2056               and then Is_OK_Fully_Initialized
2057             then
2058                return;
2059 
2060             --  Look at prefix in access type case, or if the component is not
2061             --  fully initialized.
2062 
2063             else
2064                Check_Unset_Reference (Prefix (N));
2065             end if;
2066 
2067          --  Record component
2068 
2069          when N_Selected_Component =>
2070             declare
2071                Pref : constant Node_Id   := Prefix (N);
2072                Ent  : constant Entity_Id := Entity (Selector_Name (N));
2073 
2074             begin
2075                --  If prefix involves dereferencing an access type, always
2076                --  check the prefix, since the issue then is whether this
2077                --  access value is null.
2078 
2079                if Prefix_Has_Dereference (Pref) then
2080                   null;
2081 
2082                --  Always go to prefix if no selector entity is set. Can this
2083                --  happen in the normal case? Not clear, but it definitely can
2084                --  happen in error cases.
2085 
2086                elsif No (Ent) then
2087                   null;
2088 
2089                --  For a record component, check some cases where we have
2090                --  reasonable cause to consider that the component is known to
2091                --  be or probably is initialized. In this case, we don't care
2092                --  if the prefix itself was explicitly initialized.
2093 
2094                --  Discriminants are always considered initialized
2095 
2096                elsif Ekind (Ent) = E_Discriminant then
2097                   return;
2098 
2099                --  An explicitly initialized component is certainly initialized
2100 
2101                elsif Nkind (Parent (Ent)) = N_Component_Declaration
2102                  and then Present (Expression (Parent (Ent)))
2103                then
2104                   return;
2105 
2106                --  A fully initialized component is initialized
2107 
2108                elsif Is_OK_Fully_Initialized then
2109                   return;
2110                end if;
2111 
2112                --  If none of those cases apply, check the record type prefix
2113 
2114                Check_Unset_Reference (Pref);
2115             end;
2116 
2117          --  For type conversions, qualifications, or expressions with actions,
2118          --  examine the expression.
2119 
2120          when N_Type_Conversion         |
2121               N_Qualified_Expression    |
2122               N_Expression_With_Actions =>
2123             Check_Unset_Reference (Expression (N));
2124 
2125          --  For explicit dereference, always check prefix, which will generate
2126          --  an unset reference (since this is a case of dereferencing null).
2127 
2128          when N_Explicit_Dereference =>
2129             Check_Unset_Reference (Prefix (N));
2130 
2131          --  All other cases are not cases of an unset reference
2132 
2133          when others =>
2134             null;
2135 
2136       end case;
2137    end Check_Unset_Reference;
2138 
2139    ------------------------
2140    -- Check_Unused_Withs --
2141    ------------------------
2142 
2143    procedure Check_Unused_Withs (Spec_Unit : Unit_Number_Type := No_Unit) is
2144       Cnode : Node_Id;
2145       Item  : Node_Id;
2146       Lunit : Node_Id;
2147       Ent   : Entity_Id;
2148 
2149       Munite : constant Entity_Id := Cunit_Entity (Main_Unit);
2150       --  This is needed for checking the special renaming case
2151 
2152       procedure Check_One_Unit (Unit : Unit_Number_Type);
2153       --  Subsidiary procedure, performs checks for specified unit
2154 
2155       --------------------
2156       -- Check_One_Unit --
2157       --------------------
2158 
2159       procedure Check_One_Unit (Unit : Unit_Number_Type) is
2160          Is_Visible_Renaming : Boolean := False;
2161          Pack                : Entity_Id;
2162 
2163          procedure Check_Inner_Package (Pack : Entity_Id);
2164          --  Pack is a package local to a unit in a with_clause. Both the unit
2165          --  and Pack are referenced. If none of the entities in Pack are
2166          --  referenced, then the only occurrence of Pack is in a USE clause
2167          --  or a pragma, and a warning is worthwhile as well.
2168 
2169          function Check_System_Aux return Boolean;
2170          --  Before giving a warning on a with_clause for System, check whether
2171          --  a system extension is present.
2172 
2173          function Find_Package_Renaming
2174            (P : Entity_Id;
2175             L : Entity_Id) return Entity_Id;
2176          --  The only reference to a context unit may be in a renaming
2177          --  declaration. If this renaming declares a visible entity, do not
2178          --  warn that the context clause could be moved to the body, because
2179          --  the renaming may be intended to re-export the unit.
2180 
2181          function Has_Visible_Entities (P : Entity_Id) return Boolean;
2182          --  This function determines if a package has any visible entities.
2183          --  True is returned if there is at least one declared visible entity,
2184          --  otherwise False is returned (e.g. case of only pragmas present).
2185 
2186          -------------------------
2187          -- Check_Inner_Package --
2188          -------------------------
2189 
2190          procedure Check_Inner_Package (Pack : Entity_Id) is
2191             E  : Entity_Id;
2192             Un : constant Node_Id := Sinfo.Unit (Cnode);
2193 
2194             function Check_Use_Clause (N : Node_Id) return Traverse_Result;
2195             --  If N is a use_clause for Pack, emit warning
2196 
2197             procedure Check_Use_Clauses is new
2198               Traverse_Proc (Check_Use_Clause);
2199 
2200             ----------------------
2201             -- Check_Use_Clause --
2202             ----------------------
2203 
2204             function Check_Use_Clause (N : Node_Id) return Traverse_Result is
2205                Nam  : Node_Id;
2206 
2207             begin
2208                if Nkind (N) = N_Use_Package_Clause then
2209                   Nam := First (Names (N));
2210                   while Present (Nam) loop
2211                      if Entity (Nam) = Pack then
2212 
2213                         --  Suppress message if any serious errors detected
2214                         --  that turn off expansion, and thus result in false
2215                         --  positives for this warning.
2216 
2217                         if Serious_Errors_Detected = 0 then
2218                            Error_Msg_Qual_Level := 1;
2219                            Error_Msg_NE -- CODEFIX
2220                              ("?u?no entities of package& are referenced!",
2221                                 Nam, Pack);
2222                            Error_Msg_Qual_Level := 0;
2223                         end if;
2224                      end if;
2225 
2226                      Next (Nam);
2227                   end loop;
2228                end if;
2229 
2230                return OK;
2231             end Check_Use_Clause;
2232 
2233          --  Start of processing for Check_Inner_Package
2234 
2235          begin
2236             E := First_Entity (Pack);
2237             while Present (E) loop
2238                if Referenced_Check_Spec (E) then
2239                   return;
2240                end if;
2241 
2242                Next_Entity (E);
2243             end loop;
2244 
2245             --  No entities of the package are referenced. Check whether the
2246             --  reference to the package itself is a use clause, and if so
2247             --  place a warning on it.
2248 
2249             Check_Use_Clauses (Un);
2250          end Check_Inner_Package;
2251 
2252          ----------------------
2253          -- Check_System_Aux --
2254          ----------------------
2255 
2256          function Check_System_Aux return Boolean is
2257             Ent : Entity_Id;
2258 
2259          begin
2260             if Chars (Lunit) = Name_System
2261                and then Scope (Lunit) = Standard_Standard
2262                and then Present_System_Aux
2263             then
2264                Ent := First_Entity (System_Aux_Id);
2265                while Present (Ent) loop
2266                   if Referenced_Check_Spec (Ent) then
2267                      return True;
2268                   end if;
2269 
2270                   Next_Entity (Ent);
2271                end loop;
2272             end if;
2273 
2274             return False;
2275          end Check_System_Aux;
2276 
2277          ---------------------------
2278          -- Find_Package_Renaming --
2279          ---------------------------
2280 
2281          function Find_Package_Renaming
2282            (P : Entity_Id;
2283             L : Entity_Id) return Entity_Id
2284          is
2285             E1 : Entity_Id;
2286             R  : Entity_Id;
2287 
2288          begin
2289             Is_Visible_Renaming := False;
2290 
2291             E1 := First_Entity (P);
2292             while Present (E1) loop
2293                if Ekind (E1) = E_Package and then Renamed_Object (E1) = L then
2294                   Is_Visible_Renaming := not Is_Hidden (E1);
2295                   return E1;
2296 
2297                elsif Ekind (E1) = E_Package
2298                  and then No (Renamed_Object (E1))
2299                  and then not Is_Generic_Instance (E1)
2300                then
2301                   R := Find_Package_Renaming (E1, L);
2302 
2303                   if Present (R) then
2304                      Is_Visible_Renaming := not Is_Hidden (R);
2305                      return R;
2306                   end if;
2307                end if;
2308 
2309                Next_Entity (E1);
2310             end loop;
2311 
2312             return Empty;
2313          end Find_Package_Renaming;
2314 
2315          --------------------------
2316          -- Has_Visible_Entities --
2317          --------------------------
2318 
2319          function Has_Visible_Entities (P : Entity_Id) return Boolean is
2320             E : Entity_Id;
2321 
2322          begin
2323             --  If unit in context is not a package, it is a subprogram that
2324             --  is not called or a generic unit that is not instantiated
2325             --  in the current unit, and warning is appropriate.
2326 
2327             if Ekind (P) /= E_Package then
2328                return True;
2329             end if;
2330 
2331             --  If unit comes from a limited_with clause, look for declaration
2332             --  of shadow entities.
2333 
2334             if Present (Limited_View (P)) then
2335                E := First_Entity (Limited_View (P));
2336             else
2337                E := First_Entity (P);
2338             end if;
2339 
2340             while Present (E) and then E /= First_Private_Entity (P) loop
2341                if Comes_From_Source (E) or else Present (Limited_View (P)) then
2342                   return True;
2343                end if;
2344 
2345                Next_Entity (E);
2346             end loop;
2347 
2348             return False;
2349          end Has_Visible_Entities;
2350 
2351       --  Start of processing for Check_One_Unit
2352 
2353       begin
2354          Cnode := Cunit (Unit);
2355 
2356          --  Only do check in units that are part of the extended main unit.
2357          --  This is actually a necessary restriction, because in the case of
2358          --  subprogram acting as its own specification, there can be with's in
2359          --  subunits that we will not see.
2360 
2361          if not In_Extended_Main_Source_Unit (Cnode) then
2362             return;
2363 
2364          --  In configurable run time mode, we remove the bodies of non-inlined
2365          --  subprograms, which may lead to spurious warnings, which are
2366          --  clearly undesirable.
2367 
2368          elsif Configurable_Run_Time_Mode
2369            and then Is_Predefined_File_Name (Unit_File_Name (Unit))
2370          then
2371             return;
2372          end if;
2373 
2374          --  Loop through context items in this unit
2375 
2376          Item := First (Context_Items (Cnode));
2377          while Present (Item) loop
2378             if Nkind (Item) = N_With_Clause
2379               and then not Implicit_With (Item)
2380               and then In_Extended_Main_Source_Unit (Item)
2381 
2382               --  Guard for no entity present. Not clear under what conditions
2383               --  this happens, but it does occur, and since this is only a
2384               --  warning, we just suppress the warning in this case.
2385 
2386               and then Nkind (Name (Item)) in N_Has_Entity
2387               and then Present (Entity (Name (Item)))
2388             then
2389                Lunit := Entity (Name (Item));
2390 
2391                --  Check if this unit is referenced (skip the check if this
2392                --  is explicitly marked by a pragma Unreferenced).
2393 
2394                if not Referenced (Lunit) and then not Has_Unreferenced (Lunit)
2395                then
2396                   --  Suppress warnings in internal units if not in -gnatg mode
2397                   --  (these would be junk warnings for an application program,
2398                   --  since they refer to problems in internal units).
2399 
2400                   if GNAT_Mode
2401                     or else not Is_Internal_File_Name (Unit_File_Name (Unit))
2402                   then
2403                      --  Here we definitely have a non-referenced unit. If it
2404                      --  is the special call for a spec unit, then just set the
2405                      --  flag to be read later.
2406 
2407                      if Unit = Spec_Unit then
2408                         Set_Unreferenced_In_Spec (Item);
2409 
2410                      --  Otherwise simple unreferenced message, but skip this
2411                      --  if no visible entities, because that is most likely a
2412                      --  case where warning would be false positive (e.g. a
2413                      --  package with only a linker options pragma and nothing
2414                      --  else or a pragma elaborate with a body library task).
2415 
2416                      elsif Has_Visible_Entities (Entity (Name (Item))) then
2417                         Error_Msg_N -- CODEFIX
2418                           ("?u?unit& is not referenced!", Name (Item));
2419                      end if;
2420                   end if;
2421 
2422                --  If main unit is a renaming of this unit, then we consider
2423                --  the with to be OK (obviously it is needed in this case).
2424                --  This may be transitive: the unit in the with_clause may
2425                --  itself be a renaming, in which case both it and the main
2426                --  unit rename the same ultimate package.
2427 
2428                elsif Present (Renamed_Entity (Munite))
2429                   and then
2430                     (Renamed_Entity (Munite) = Lunit
2431                       or else Renamed_Entity (Munite) = Renamed_Entity (Lunit))
2432                then
2433                   null;
2434 
2435                --  If this unit is referenced, and it is a package, we do
2436                --  another test, to see if any of the entities in the package
2437                --  are referenced. If none of the entities are referenced, we
2438                --  still post a warning. This occurs if the only use of the
2439                --  package is in a use clause, or in a package renaming
2440                --  declaration. This check is skipped for packages that are
2441                --  renamed in a spec, since the entities in such a package are
2442                --  visible to clients via the renaming.
2443 
2444                elsif Ekind (Lunit) = E_Package
2445                  and then not Renamed_In_Spec (Lunit)
2446                then
2447                   --  If Is_Instantiated is set, it means that the package is
2448                   --  implicitly instantiated (this is the case of parent
2449                   --  instance or an actual for a generic package formal), and
2450                   --  this counts as a reference.
2451 
2452                   if Is_Instantiated (Lunit) then
2453                      null;
2454 
2455                   --  If no entities in package, and there is a pragma
2456                   --  Elaborate_Body present, then assume that this with is
2457                   --  done for purposes of this elaboration.
2458 
2459                   elsif No (First_Entity (Lunit))
2460                     and then Has_Pragma_Elaborate_Body (Lunit)
2461                   then
2462                      null;
2463 
2464                   --  Otherwise see if any entities have been referenced
2465 
2466                   else
2467                      if Limited_Present (Item) then
2468                         Ent := First_Entity (Limited_View (Lunit));
2469                      else
2470                         Ent := First_Entity (Lunit);
2471                      end if;
2472 
2473                      loop
2474                         --  No more entities, and we did not find one that was
2475                         --  referenced. Means we have a definite case of a with
2476                         --  none of whose entities was referenced.
2477 
2478                         if No (Ent) then
2479 
2480                            --  If in spec, just set the flag
2481 
2482                            if Unit = Spec_Unit then
2483                               Set_No_Entities_Ref_In_Spec (Item);
2484 
2485                            elsif Check_System_Aux then
2486                               null;
2487 
2488                            --  Else the warning may be needed
2489 
2490                            else
2491                               declare
2492                                  Eitem : constant Entity_Id :=
2493                                            Entity (Name (Item));
2494 
2495                               begin
2496                                  --  Warn if we unreferenced flag set and we
2497                                  --  have not had serious errors. The reason we
2498                                  --  inhibit the message if there are errors is
2499                                  --  to prevent false positives from disabling
2500                                  --  expansion.
2501 
2502                                  if not Has_Unreferenced (Eitem)
2503                                    and then Serious_Errors_Detected = 0
2504                                  then
2505                                     --  Get possible package renaming
2506 
2507                                     Pack :=
2508                                       Find_Package_Renaming (Munite, Lunit);
2509 
2510                                     --  No warning if either the package or its
2511                                     --  renaming is used as a generic actual.
2512 
2513                                     if Used_As_Generic_Actual (Eitem)
2514                                       or else
2515                                         (Present (Pack)
2516                                           and then
2517                                             Used_As_Generic_Actual (Pack))
2518                                     then
2519                                        exit;
2520                                     end if;
2521 
2522                                     --  Here we give the warning
2523 
2524                                     Error_Msg_N -- CODEFIX
2525                                       ("?u?no entities of & are referenced!",
2526                                        Name (Item));
2527 
2528                                     --  Flag renaming of package as well. If
2529                                     --  the original package has warnings off,
2530                                     --  we suppress the warning on the renaming
2531                                     --  as well.
2532 
2533                                     if Present (Pack)
2534                                       and then not Has_Warnings_Off (Lunit)
2535                                       and then not Has_Unreferenced (Pack)
2536                                     then
2537                                        Error_Msg_NE -- CODEFIX
2538                                          ("?u?no entities of& are referenced!",
2539                                           Unit_Declaration_Node (Pack), Pack);
2540                                     end if;
2541                                  end if;
2542                               end;
2543                            end if;
2544 
2545                            exit;
2546 
2547                         --  Case of entity being referenced. The reference may
2548                         --  come from a limited_with_clause, in which case the
2549                         --  limited view of the entity carries the flag.
2550 
2551                         elsif Referenced_Check_Spec (Ent)
2552                           or else Referenced_As_LHS_Check_Spec (Ent)
2553                           or else Referenced_As_Out_Parameter_Check_Spec (Ent)
2554                           or else
2555                             (From_Limited_With (Ent)
2556                               and then Is_Incomplete_Type (Ent)
2557                               and then Present (Non_Limited_View (Ent))
2558                               and then Referenced (Non_Limited_View (Ent)))
2559                         then
2560                            --  This means that the with is indeed fine, in that
2561                            --  it is definitely needed somewhere, and we can
2562                            --  quit worrying about this one...
2563 
2564                            --  Except for one little detail: if either of the
2565                            --  flags was set during spec processing, this is
2566                            --  where we complain that the with could be moved
2567                            --  from the spec. If the spec contains a visible
2568                            --  renaming of the package, inhibit warning to move
2569                            --  with_clause to body.
2570 
2571                            if Ekind (Munite) = E_Package_Body then
2572                               Pack :=
2573                                 Find_Package_Renaming
2574                                   (Spec_Entity (Munite), Lunit);
2575                            else
2576                               Pack := Empty;
2577                            end if;
2578 
2579                            --  If a renaming is present in the spec do not warn
2580                            --  because the body or child unit may depend on it.
2581 
2582                            if Present (Pack)
2583                              and then Renamed_Entity (Pack) = Lunit
2584                            then
2585                               exit;
2586 
2587                            elsif Unreferenced_In_Spec (Item) then
2588                               Error_Msg_N -- CODEFIX
2589                                 ("?u?unit& is not referenced in spec!",
2590                                  Name (Item));
2591 
2592                            elsif No_Entities_Ref_In_Spec (Item) then
2593                               Error_Msg_N -- CODEFIX
2594                                 ("?u?no entities of & are referenced in spec!",
2595                                  Name (Item));
2596 
2597                            else
2598                               if Ekind (Ent) = E_Package then
2599                                  Check_Inner_Package (Ent);
2600                               end if;
2601 
2602                               exit;
2603                            end if;
2604 
2605                            if not Is_Visible_Renaming then
2606                               Error_Msg_N -- CODEFIX
2607                                 ("\?u?with clause might be moved to body!",
2608                                  Name (Item));
2609                            end if;
2610 
2611                            exit;
2612 
2613                         --  Move to next entity to continue search
2614 
2615                         else
2616                            Next_Entity (Ent);
2617                         end if;
2618                      end loop;
2619                   end if;
2620 
2621                --  For a generic package, the only interesting kind of
2622                --  reference is an instantiation, since entities cannot be
2623                --  referenced directly.
2624 
2625                elsif Is_Generic_Unit (Lunit) then
2626 
2627                   --  Unit was never instantiated, set flag for case of spec
2628                   --  call, or give warning for normal call.
2629 
2630                   if not Is_Instantiated (Lunit) then
2631                      if Unit = Spec_Unit then
2632                         Set_Unreferenced_In_Spec (Item);
2633                      else
2634                         Error_Msg_N -- CODEFIX
2635                           ("?u?unit& is never instantiated!", Name (Item));
2636                      end if;
2637 
2638                   --  If unit was indeed instantiated, make sure that flag is
2639                   --  not set showing it was uninstantiated in the spec, and if
2640                   --  so, give warning.
2641 
2642                   elsif Unreferenced_In_Spec (Item) then
2643                      Error_Msg_N
2644                        ("?u?unit& is not instantiated in spec!", Name (Item));
2645                      Error_Msg_N -- CODEFIX
2646                        ("\?u?with clause can be moved to body!", Name (Item));
2647                   end if;
2648                end if;
2649             end if;
2650 
2651             Next (Item);
2652          end loop;
2653       end Check_One_Unit;
2654 
2655    --  Start of processing for Check_Unused_Withs
2656 
2657    begin
2658       --  Immediate return if no semantics or warning flag not set
2659 
2660       if not Opt.Check_Withs or else Operating_Mode = Check_Syntax then
2661          return;
2662       end if;
2663 
2664       Process_Deferred_References;
2665 
2666       --  Flag any unused with clauses. For a subunit, check only the units
2667       --  in its context, not those of the parent, which may be needed by other
2668       --  subunits.  We will get the full warnings when we compile the parent,
2669       --  but the following is helpful when compiling a subunit by itself.
2670 
2671       if Nkind (Unit (Cunit (Main_Unit))) = N_Subunit then
2672          if Current_Sem_Unit = Main_Unit then
2673             Check_One_Unit (Main_Unit);
2674          end if;
2675 
2676          return;
2677       end if;
2678 
2679       --  Process specified units
2680 
2681       if Spec_Unit = No_Unit then
2682 
2683          --  For main call, check all units
2684 
2685          for Unit in Main_Unit .. Last_Unit loop
2686             Check_One_Unit (Unit);
2687          end loop;
2688 
2689       else
2690          --  For call for spec, check only the spec
2691 
2692          Check_One_Unit (Spec_Unit);
2693       end if;
2694    end Check_Unused_Withs;
2695 
2696    ---------------------------------
2697    -- Generic_Package_Spec_Entity --
2698    ---------------------------------
2699 
2700    function Generic_Package_Spec_Entity (E : Entity_Id) return Boolean is
2701       S : Entity_Id;
2702 
2703    begin
2704       if Is_Package_Body_Entity (E) then
2705          return False;
2706 
2707       else
2708          S := Scope (E);
2709          loop
2710             if S = Standard_Standard then
2711                return False;
2712 
2713             elsif Ekind (S) = E_Generic_Package then
2714                return True;
2715 
2716             elsif Ekind (S) = E_Package then
2717                S := Scope (S);
2718 
2719             else
2720                return False;
2721             end if;
2722          end loop;
2723       end if;
2724    end Generic_Package_Spec_Entity;
2725 
2726    ----------------------
2727    -- Goto_Spec_Entity --
2728    ----------------------
2729 
2730    function Goto_Spec_Entity (E : Entity_Id) return Entity_Id is
2731    begin
2732       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2733          return Spec_Entity (E);
2734       else
2735          return E;
2736       end if;
2737    end Goto_Spec_Entity;
2738 
2739    -------------------
2740    -- Has_Junk_Name --
2741    -------------------
2742 
2743    function Has_Junk_Name (E : Entity_Id) return Boolean is
2744       function Match (S : String) return Boolean;
2745       --  Return true if substring S is found in Name_Buffer (1 .. Name_Len)
2746 
2747       -----------
2748       -- Match --
2749       -----------
2750 
2751       function Match (S : String) return Boolean is
2752          Slen1 : constant Integer := S'Length - 1;
2753 
2754       begin
2755          for J in 1 .. Name_Len - S'Length + 1 loop
2756             if Name_Buffer (J .. J + Slen1) = S then
2757                return True;
2758             end if;
2759          end loop;
2760 
2761          return False;
2762       end Match;
2763 
2764    --  Start of processing for Has_Junk_Name
2765 
2766    begin
2767       Get_Unqualified_Decoded_Name_String (Chars (E));
2768 
2769       return
2770         Match ("discard") or else
2771         Match ("dummy")   or else
2772         Match ("ignore")  or else
2773         Match ("junk")    or else
2774         Match ("unused");
2775    end Has_Junk_Name;
2776 
2777    --------------------------------------
2778    -- Has_Pragma_Unmodified_Check_Spec --
2779    --------------------------------------
2780 
2781    function Has_Pragma_Unmodified_Check_Spec
2782      (E : Entity_Id) return Boolean
2783    is
2784    begin
2785       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2786 
2787          --  Note: use of OR instead of OR ELSE here is deliberate, we want
2788          --  to mess with Unmodified flags on both body and spec entities.
2789 
2790          return Has_Unmodified (E)
2791                   or
2792                 Has_Unmodified (Spec_Entity (E));
2793 
2794       else
2795          return Has_Unmodified (E);
2796       end if;
2797    end Has_Pragma_Unmodified_Check_Spec;
2798 
2799    ----------------------------------------
2800    -- Has_Pragma_Unreferenced_Check_Spec --
2801    ----------------------------------------
2802 
2803    function Has_Pragma_Unreferenced_Check_Spec
2804      (E : Entity_Id) return Boolean
2805    is
2806    begin
2807       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2808 
2809          --  Note: use of OR here instead of OR ELSE is deliberate, we want
2810          --  to mess with flags on both entities.
2811 
2812          return Has_Unreferenced (E)
2813                   or
2814                 Has_Unreferenced (Spec_Entity (E));
2815 
2816       else
2817          return Has_Unreferenced (E);
2818       end if;
2819    end Has_Pragma_Unreferenced_Check_Spec;
2820 
2821    ----------------
2822    -- Initialize --
2823    ----------------
2824 
2825    procedure Initialize is
2826    begin
2827       Warnings_Off_Pragmas.Init;
2828       Unreferenced_Entities.Init;
2829       In_Out_Warnings.Init;
2830    end Initialize;
2831 
2832    ------------------------------------
2833    -- Never_Set_In_Source_Check_Spec --
2834    ------------------------------------
2835 
2836    function Never_Set_In_Source_Check_Spec (E : Entity_Id) return Boolean is
2837    begin
2838       if Is_Formal (E) and then Present (Spec_Entity (E)) then
2839          return Never_Set_In_Source (E)
2840                   and then
2841                 Never_Set_In_Source (Spec_Entity (E));
2842       else
2843          return Never_Set_In_Source (E);
2844       end if;
2845    end Never_Set_In_Source_Check_Spec;
2846 
2847    -------------------------------------
2848    -- Operand_Has_Warnings_Suppressed --
2849    -------------------------------------
2850 
2851    function Operand_Has_Warnings_Suppressed (N : Node_Id) return Boolean is
2852 
2853       function Check_For_Warnings (N : Node_Id) return Traverse_Result;
2854       --  Function used to check one node to see if it is or was originally
2855       --  a reference to an entity for which Warnings are off. If so, Abandon
2856       --  is returned, otherwise OK_Orig is returned to continue the traversal
2857       --  of the original expression.
2858 
2859       function Traverse is new Traverse_Func (Check_For_Warnings);
2860       --  Function used to traverse tree looking for warnings
2861 
2862       ------------------------
2863       -- Check_For_Warnings --
2864       ------------------------
2865 
2866       function Check_For_Warnings (N : Node_Id) return Traverse_Result is
2867          R : constant Node_Id := Original_Node (N);
2868 
2869       begin
2870          if Nkind (R) in N_Has_Entity
2871            and then Present (Entity (R))
2872            and then Has_Warnings_Off (Entity (R))
2873          then
2874             return Abandon;
2875          else
2876             return OK_Orig;
2877          end if;
2878       end Check_For_Warnings;
2879 
2880    --  Start of processing for Operand_Has_Warnings_Suppressed
2881 
2882    begin
2883       return Traverse (N) = Abandon;
2884 
2885    --  If any exception occurs, then something has gone wrong, and this is
2886    --  only a minor aesthetic issue anyway, so just say we did not find what
2887    --  we are looking for, rather than blow up.
2888 
2889    exception
2890       when others =>
2891          return False;
2892    end Operand_Has_Warnings_Suppressed;
2893 
2894    -----------------------------------------
2895    -- Output_Non_Modified_In_Out_Warnings --
2896    -----------------------------------------
2897 
2898    procedure Output_Non_Modified_In_Out_Warnings is
2899 
2900       function No_Warn_On_In_Out (E : Entity_Id) return Boolean;
2901       --  Given a formal parameter entity E, determines if there is a reason to
2902       --  suppress IN OUT warnings (not modified, could be IN) for formals of
2903       --  the subprogram. We suppress these warnings if Warnings Off is set, or
2904       --  if we have seen the address of the subprogram being taken, or if the
2905       --  subprogram is used as a generic actual (in the latter cases the
2906       --  context may force use of IN OUT, even if the parameter is not
2907       --  modifies for this particular case.
2908 
2909       -----------------------
2910       -- No_Warn_On_In_Out --
2911       -----------------------
2912 
2913       function No_Warn_On_In_Out (E : Entity_Id) return Boolean is
2914          S  : constant Entity_Id := Scope (E);
2915          SE : constant Entity_Id := Spec_Entity (E);
2916 
2917       begin
2918          --  Do not warn if address is taken, since funny business may be going
2919          --  on in treating the parameter indirectly as IN OUT.
2920 
2921          if Address_Taken (S)
2922            or else (Present (SE) and then Address_Taken (Scope (SE)))
2923          then
2924             return True;
2925 
2926          --  Do not warn if used as a generic actual, since the generic may be
2927          --  what is forcing the use of an "unnecessary" IN OUT.
2928 
2929          elsif Used_As_Generic_Actual (S)
2930            or else (Present (SE) and then Used_As_Generic_Actual (Scope (SE)))
2931          then
2932             return True;
2933 
2934          --  Else test warnings off
2935 
2936          elsif Warnings_Off_Check_Spec (S) then
2937             return True;
2938 
2939          --  All tests for suppressing warning failed
2940 
2941          else
2942             return False;
2943          end if;
2944       end No_Warn_On_In_Out;
2945 
2946    --  Start of processing for Output_Non_Modified_In_Out_Warnings
2947 
2948    begin
2949       --  Loop through entities for which a warning may be needed
2950 
2951       for J in In_Out_Warnings.First .. In_Out_Warnings.Last loop
2952          declare
2953             E1 : constant Entity_Id := In_Out_Warnings.Table (J);
2954 
2955          begin
2956             --  Suppress warning in specific cases (see details in comments for
2957             --  No_Warn_On_In_Out), or if there is a pragma Unmodified.
2958 
2959             if Has_Pragma_Unmodified_Check_Spec (E1)
2960               or else No_Warn_On_In_Out (E1)
2961             then
2962                null;
2963 
2964             --  Here we generate the warning
2965 
2966             else
2967                --  If -gnatwc is set then output message that we could be IN
2968 
2969                if not Is_Trivial_Subprogram (Scope (E1)) then
2970                   if Warn_On_Constant then
2971                      Error_Msg_N
2972                        ("?u?formal parameter & is not modified!", E1);
2973                      Error_Msg_N
2974                        ("\?u?mode could be IN instead of `IN OUT`!", E1);
2975 
2976                      --  We do not generate warnings for IN OUT parameters
2977                      --  unless we have at least -gnatwu. This is deliberately
2978                      --  inconsistent with the treatment of variables, but
2979                      --  otherwise we get too many unexpected warnings in
2980                      --  default mode.
2981 
2982                   elsif Check_Unreferenced then
2983                      Error_Msg_N
2984                        ("?u?formal parameter& is read but "
2985                         & "never assigned!", E1);
2986                   end if;
2987                end if;
2988 
2989                --  Kill any other warnings on this entity, since this is the
2990                --  one that should dominate any other unreferenced warning.
2991 
2992                Set_Warnings_Off (E1);
2993             end if;
2994          end;
2995       end loop;
2996    end Output_Non_Modified_In_Out_Warnings;
2997 
2998    ----------------------------------------
2999    -- Output_Obsolescent_Entity_Warnings --
3000    ----------------------------------------
3001 
3002    procedure Output_Obsolescent_Entity_Warnings (N : Node_Id; E : Entity_Id) is
3003       P : constant Node_Id := Parent (N);
3004       S : Entity_Id;
3005 
3006    begin
3007       S := Current_Scope;
3008 
3009       --  Do not output message if we are the scope of standard. This means
3010       --  we have a reference from a context clause from when it is originally
3011       --  processed, and that's too early to tell whether it is an obsolescent
3012       --  unit doing the with'ing. In Sem_Ch10.Analyze_Compilation_Unit we make
3013       --  sure that we have a later call when the scope is available. This test
3014       --  also eliminates all messages for use clauses, which is fine (we do
3015       --  not want messages for use clauses, since they are always redundant
3016       --  with respect to the associated with clause).
3017 
3018       if S = Standard_Standard then
3019          return;
3020       end if;
3021 
3022       --  Do not output message if we are in scope of an obsolescent package
3023       --  or subprogram.
3024 
3025       loop
3026          if Is_Obsolescent (S) then
3027             return;
3028          end if;
3029 
3030          S := Scope (S);
3031          exit when S = Standard_Standard;
3032       end loop;
3033 
3034       --  Here we will output the message
3035 
3036       Error_Msg_Sloc := Sloc (E);
3037 
3038       --  Case of with clause
3039 
3040       if Nkind (P) = N_With_Clause then
3041          if Ekind (E) = E_Package then
3042             Error_Msg_NE
3043               ("?j?with of obsolescent package& declared#", N, E);
3044          elsif Ekind (E) = E_Procedure then
3045             Error_Msg_NE
3046               ("?j?with of obsolescent procedure& declared#", N, E);
3047          else
3048             Error_Msg_NE
3049               ("??with of obsolescent function& declared#", N, E);
3050          end if;
3051 
3052       --  If we do not have a with clause, then ignore any reference to an
3053       --  obsolescent package name. We only want to give the one warning of
3054       --  withing the package, not one each time it is used to qualify.
3055 
3056       elsif Ekind (E) = E_Package then
3057          return;
3058 
3059       --  Procedure call statement
3060 
3061       elsif Nkind (P) = N_Procedure_Call_Statement then
3062          Error_Msg_NE
3063            ("??call to obsolescent procedure& declared#", N, E);
3064 
3065       --  Function call
3066 
3067       elsif Nkind (P) = N_Function_Call then
3068          Error_Msg_NE
3069            ("??call to obsolescent function& declared#", N, E);
3070 
3071       --  Reference to obsolescent type
3072 
3073       elsif Is_Type (E) then
3074          Error_Msg_NE
3075            ("??reference to obsolescent type& declared#", N, E);
3076 
3077       --  Reference to obsolescent component
3078 
3079       elsif Ekind_In (E, E_Component, E_Discriminant) then
3080          Error_Msg_NE
3081            ("??reference to obsolescent component& declared#", N, E);
3082 
3083       --  Reference to obsolescent variable
3084 
3085       elsif Ekind (E) = E_Variable then
3086          Error_Msg_NE
3087            ("??reference to obsolescent variable& declared#", N, E);
3088 
3089       --  Reference to obsolescent constant
3090 
3091       elsif Ekind (E) = E_Constant or else Ekind (E) in Named_Kind then
3092          Error_Msg_NE
3093            ("??reference to obsolescent constant& declared#", N, E);
3094 
3095       --  Reference to obsolescent enumeration literal
3096 
3097       elsif Ekind (E) = E_Enumeration_Literal then
3098          Error_Msg_NE
3099            ("??reference to obsolescent enumeration literal& declared#", N, E);
3100 
3101       --  Generic message for any other case we missed
3102 
3103       else
3104          Error_Msg_NE
3105            ("??reference to obsolescent entity& declared#", N, E);
3106       end if;
3107 
3108       --  Output additional warning if present
3109 
3110       for J in Obsolescent_Warnings.First .. Obsolescent_Warnings.Last loop
3111          if Obsolescent_Warnings.Table (J).Ent = E then
3112             String_To_Name_Buffer (Obsolescent_Warnings.Table (J).Msg);
3113             Error_Msg_Strlen := Name_Len;
3114             Error_Msg_String (1 .. Name_Len) := Name_Buffer (1 .. Name_Len);
3115             Error_Msg_N ("\\??~", N);
3116             exit;
3117          end if;
3118       end loop;
3119    end Output_Obsolescent_Entity_Warnings;
3120 
3121    ----------------------------------
3122    -- Output_Unreferenced_Messages --
3123    ----------------------------------
3124 
3125    procedure Output_Unreferenced_Messages is
3126    begin
3127       for J in Unreferenced_Entities.First .. Unreferenced_Entities.Last loop
3128          Warn_On_Unreferenced_Entity (Unreferenced_Entities.Table (J));
3129       end loop;
3130    end Output_Unreferenced_Messages;
3131 
3132    -----------------------------------------
3133    -- Output_Unused_Warnings_Off_Warnings --
3134    -----------------------------------------
3135 
3136    procedure Output_Unused_Warnings_Off_Warnings is
3137    begin
3138       for J in Warnings_Off_Pragmas.First .. Warnings_Off_Pragmas.Last loop
3139          declare
3140             Wentry : Warnings_Off_Entry renames Warnings_Off_Pragmas.Table (J);
3141             N      : Node_Id renames Wentry.N;
3142             E      : Node_Id renames Wentry.E;
3143 
3144          begin
3145             --  Turn off Warnings_Off, or we won't get the warning
3146 
3147             Set_Warnings_Off (E, False);
3148 
3149             --  Nothing to do if pragma was used to suppress a general warning
3150 
3151             if Warnings_Off_Used (E) then
3152                null;
3153 
3154             --  If pragma was used both in unmodified and unreferenced contexts
3155             --  then that's as good as the general case, no warning.
3156 
3157             elsif Warnings_Off_Used_Unmodified (E)
3158                     and
3159                   Warnings_Off_Used_Unreferenced (E)
3160             then
3161                null;
3162 
3163             --  Used only in context where Unmodified would have worked
3164 
3165             elsif Warnings_Off_Used_Unmodified (E) then
3166                Error_Msg_NE
3167                  ("?W?could use Unmodified instead of "
3168                   & "Warnings Off for &", Pragma_Identifier (N), E);
3169 
3170             --  Used only in context where Unreferenced would have worked
3171 
3172             elsif Warnings_Off_Used_Unreferenced (E) then
3173                Error_Msg_NE
3174                  ("?W?could use Unreferenced instead of "
3175                   & "Warnings Off for &", Pragma_Identifier (N), E);
3176 
3177             --  Not used at all
3178 
3179             else
3180                Error_Msg_NE
3181                  ("?W?pragma Warnings Off for & unused, "
3182                   & "could be omitted", N, E);
3183             end if;
3184          end;
3185       end loop;
3186    end Output_Unused_Warnings_Off_Warnings;
3187 
3188    ---------------------------
3189    -- Referenced_Check_Spec --
3190    ---------------------------
3191 
3192    function Referenced_Check_Spec (E : Entity_Id) return Boolean is
3193    begin
3194       if Is_Formal (E) and then Present (Spec_Entity (E)) then
3195          return Referenced (E) or else Referenced (Spec_Entity (E));
3196       else
3197          return Referenced (E);
3198       end if;
3199    end Referenced_Check_Spec;
3200 
3201    ----------------------------------
3202    -- Referenced_As_LHS_Check_Spec --
3203    ----------------------------------
3204 
3205    function Referenced_As_LHS_Check_Spec (E : Entity_Id) return Boolean is
3206    begin
3207       if Is_Formal (E) and then Present (Spec_Entity (E)) then
3208          return Referenced_As_LHS (E)
3209            or else Referenced_As_LHS (Spec_Entity (E));
3210       else
3211          return Referenced_As_LHS (E);
3212       end if;
3213    end Referenced_As_LHS_Check_Spec;
3214 
3215    --------------------------------------------
3216    -- Referenced_As_Out_Parameter_Check_Spec --
3217    --------------------------------------------
3218 
3219    function Referenced_As_Out_Parameter_Check_Spec
3220      (E : Entity_Id) return Boolean
3221    is
3222    begin
3223       if Is_Formal (E) and then Present (Spec_Entity (E)) then
3224          return Referenced_As_Out_Parameter (E)
3225            or else Referenced_As_Out_Parameter (Spec_Entity (E));
3226       else
3227          return Referenced_As_Out_Parameter (E);
3228       end if;
3229    end Referenced_As_Out_Parameter_Check_Spec;
3230 
3231    -----------------------------
3232    -- Warn_On_Known_Condition --
3233    -----------------------------
3234 
3235    procedure Warn_On_Known_Condition (C : Node_Id) is
3236       P           : Node_Id;
3237       Orig        : constant Node_Id := Original_Node (C);
3238       Test_Result : Boolean;
3239 
3240       function Is_Known_Branch return Boolean;
3241       --  If the type of the condition is Boolean, the constant value of the
3242       --  condition is a boolean literal. If the type is a derived boolean
3243       --  type, the constant is wrapped in a type conversion of the derived
3244       --  literal. If the value of the condition is not a literal, no warnings
3245       --  can be produced. This function returns True if the result can be
3246       --  determined, and Test_Result is set True/False accordingly. Otherwise
3247       --  False is returned, and Test_Result is unchanged.
3248 
3249       procedure Track (N : Node_Id; Loc : Node_Id);
3250       --  Adds continuation warning(s) pointing to reason (assignment or test)
3251       --  for the operand of the conditional having a known value (or at least
3252       --  enough is known about the value to issue the warning). N is the node
3253       --  which is judged to have a known value. Loc is the warning location.
3254 
3255       ---------------------
3256       -- Is_Known_Branch --
3257       ---------------------
3258 
3259       function Is_Known_Branch return Boolean is
3260       begin
3261          if Etype (C) = Standard_Boolean
3262            and then Is_Entity_Name (C)
3263            and then
3264              (Entity (C) = Standard_False or else Entity (C) = Standard_True)
3265          then
3266             Test_Result := Entity (C) = Standard_True;
3267             return True;
3268 
3269          elsif Is_Boolean_Type (Etype (C))
3270            and then Nkind (C) = N_Unchecked_Type_Conversion
3271            and then Is_Entity_Name (Expression (C))
3272            and then Ekind (Entity (Expression (C))) = E_Enumeration_Literal
3273          then
3274             Test_Result :=
3275               Chars (Entity (Expression (C))) = Chars (Standard_True);
3276             return True;
3277 
3278          else
3279             return False;
3280          end if;
3281       end Is_Known_Branch;
3282 
3283       -----------
3284       -- Track --
3285       -----------
3286 
3287       procedure Track (N : Node_Id; Loc : Node_Id) is
3288          Nod : constant Node_Id := Original_Node (N);
3289 
3290       begin
3291          if Nkind (Nod) in N_Op_Compare then
3292             Track (Left_Opnd (Nod), Loc);
3293             Track (Right_Opnd (Nod), Loc);
3294 
3295          elsif Is_Entity_Name (Nod) and then Is_Object (Entity (Nod)) then
3296             declare
3297                CV : constant Node_Id := Current_Value (Entity (Nod));
3298 
3299             begin
3300                if Present (CV) then
3301                   Error_Msg_Sloc := Sloc (CV);
3302 
3303                   if Nkind (CV) not in N_Subexpr then
3304                      Error_Msg_N ("\\??(see test #)", Loc);
3305 
3306                   elsif Nkind (Parent (CV)) =
3307                           N_Case_Statement_Alternative
3308                   then
3309                      Error_Msg_N ("\\??(see case alternative #)", Loc);
3310 
3311                   else
3312                      Error_Msg_N ("\\??(see assignment #)", Loc);
3313                   end if;
3314                end if;
3315             end;
3316          end if;
3317       end Track;
3318 
3319    --  Start of processing for Warn_On_Known_Condition
3320 
3321    begin
3322       --  Adjust SCO condition if from source
3323 
3324       if Generate_SCO
3325         and then Comes_From_Source (Orig)
3326         and then Is_Known_Branch
3327       then
3328          declare
3329             Atrue : Boolean;
3330 
3331          begin
3332             Atrue := Test_Result;
3333 
3334             if Present (Parent (C)) and then Nkind (Parent (C)) = N_Op_Not then
3335                Atrue := not Atrue;
3336             end if;
3337 
3338             Set_SCO_Condition (Orig, Atrue);
3339          end;
3340       end if;
3341 
3342       --  Argument replacement in an inlined body can make conditions static.
3343       --  Do not emit warnings in this case.
3344 
3345       if In_Inlined_Body then
3346          return;
3347       end if;
3348 
3349       if Constant_Condition_Warnings
3350         and then Is_Known_Branch
3351         and then Comes_From_Source (Orig)
3352         and then not In_Instance
3353       then
3354          --  Don't warn if comparison of result of attribute against a constant
3355          --  value, since this is likely legitimate conditional compilation.
3356 
3357          if Nkind (Orig) in N_Op_Compare
3358            and then Compile_Time_Known_Value (Right_Opnd (Orig))
3359            and then Nkind (Original_Node (Left_Opnd (Orig))) =
3360                                                      N_Attribute_Reference
3361          then
3362             return;
3363          end if;
3364 
3365          --  See if this is in a statement or a declaration
3366 
3367          P := Parent (C);
3368          loop
3369             --  If tree is not attached, do not issue warning (this is very
3370             --  peculiar, and probably arises from some other error condition).
3371 
3372             if No (P) then
3373                return;
3374 
3375             --  If we are in a declaration, then no warning, since in practice
3376             --  conditionals in declarations are used for intended tests which
3377             --  may be known at compile time, e.g. things like
3378 
3379             --    x : constant Integer := 2 + (Word'Size = 32);
3380 
3381             --  And a warning is annoying in such cases
3382 
3383             elsif Nkind (P) in N_Declaration
3384                     or else
3385                   Nkind (P) in N_Later_Decl_Item
3386             then
3387                return;
3388 
3389             --  Don't warn in assert or check pragma, since presumably tests in
3390             --  such a context are very definitely intended, and might well be
3391             --  known at compile time. Note that we have to test the original
3392             --  node, since assert pragmas get rewritten at analysis time.
3393 
3394             elsif Nkind (Original_Node (P)) = N_Pragma
3395               and then Nam_In (Pragma_Name (Original_Node (P)), Name_Assert,
3396                                                                 Name_Check)
3397             then
3398                return;
3399             end if;
3400 
3401             exit when Is_Statement (P);
3402             P := Parent (P);
3403          end loop;
3404 
3405          --  Here we issue the warning unless some sub-operand has warnings
3406          --  set off, in which case we suppress the warning for the node. If
3407          --  the original expression is an inequality, it has been expanded
3408          --  into a negation, and the value of the original expression is the
3409          --  negation of the equality. If the expression is an entity that
3410          --  appears within a negation, it is clearer to flag the negation
3411          --  itself, and report on its constant value.
3412 
3413          if not Operand_Has_Warnings_Suppressed (C) then
3414             declare
3415                True_Branch : Boolean := Test_Result;
3416                Cond        : Node_Id := C;
3417 
3418             begin
3419                if Present (Parent (C))
3420                  and then Nkind (Parent (C)) = N_Op_Not
3421                then
3422                   True_Branch := not True_Branch;
3423                   Cond := Parent (C);
3424                end if;
3425 
3426                --  Condition always True
3427 
3428                if True_Branch then
3429                   if Is_Entity_Name (Original_Node (C))
3430                     and then Nkind (Cond) /= N_Op_Not
3431                   then
3432                      Error_Msg_NE
3433                        ("object & is always True at this point?c?",
3434                         Cond, Original_Node (C));
3435                      Track (Original_Node (C), Cond);
3436 
3437                   else
3438                      Error_Msg_N ("condition is always True?c?", Cond);
3439                      Track (Cond, Cond);
3440                   end if;
3441 
3442                --  Condition always False
3443 
3444                else
3445                   if Is_Entity_Name (Original_Node (C))
3446                     and then Nkind (Cond) /= N_Op_Not
3447                   then
3448                      Error_Msg_NE
3449                        ("object & is always False at this point?c?",
3450                         Cond, Original_Node (C));
3451                      Track (Original_Node (C), Cond);
3452 
3453                   else
3454                      Error_Msg_N ("condition is always False?c?", Cond);
3455                      Track (Cond, Cond);
3456                   end if;
3457                end if;
3458             end;
3459          end if;
3460       end if;
3461    end Warn_On_Known_Condition;
3462 
3463    ---------------------------------------
3464    -- Warn_On_Modified_As_Out_Parameter --
3465    ---------------------------------------
3466 
3467    function Warn_On_Modified_As_Out_Parameter (E : Entity_Id) return Boolean is
3468    begin
3469       return
3470         (Warn_On_Modified_Unread and then Is_Only_Out_Parameter (E))
3471           or else Warn_On_All_Unread_Out_Parameters;
3472    end Warn_On_Modified_As_Out_Parameter;
3473 
3474    ---------------------------------
3475    -- Warn_On_Overlapping_Actuals --
3476    ---------------------------------
3477 
3478    procedure Warn_On_Overlapping_Actuals (Subp : Entity_Id; N : Node_Id) is
3479       Act1, Act2   : Node_Id;
3480       Form1, Form2 : Entity_Id;
3481 
3482       function Is_Covered_Formal (Formal : Node_Id) return Boolean;
3483       --  Return True if Formal is covered by the rule
3484 
3485       function Refer_Same_Object (Act1, Act2 : Node_Id) return Boolean;
3486       --  Two names are known to refer to the same object if the two names
3487       --  are known to denote the same object; or one of the names is a
3488       --  selected_component, indexed_component, or slice and its prefix is
3489       --  known to refer to the same object as the other name; or one of the
3490       --  two names statically denotes a renaming declaration whose renamed
3491       --  object_name is known to refer to the same object as the other name
3492       --  (RM 6.4.1(6.11/3))
3493 
3494       -----------------------
3495       -- Refer_Same_Object --
3496       -----------------------
3497 
3498       function Refer_Same_Object (Act1, Act2 : Node_Id) return Boolean is
3499       begin
3500          return Denotes_Same_Object (Act1, Act2)
3501            or else Denotes_Same_Prefix (Act1, Act2);
3502       end Refer_Same_Object;
3503 
3504       -----------------------
3505       -- Is_Covered_Formal --
3506       -----------------------
3507 
3508       function Is_Covered_Formal (Formal : Node_Id) return Boolean is
3509       begin
3510          return
3511            Ekind_In (Formal, E_Out_Parameter, E_In_Out_Parameter)
3512              and then (Is_Elementary_Type (Etype (Formal))
3513                         or else Is_Record_Type (Etype (Formal))
3514                         or else Is_Array_Type (Etype (Formal)));
3515       end Is_Covered_Formal;
3516 
3517    begin
3518       if Ada_Version < Ada_2012 and then not Warn_On_Overlap then
3519          return;
3520       end if;
3521 
3522       --  Exclude calls rewritten as enumeration literals
3523 
3524       if Nkind (N) not in N_Subprogram_Call
3525         and then Nkind (N) /= N_Entry_Call_Statement
3526       then
3527          return;
3528       end if;
3529 
3530       --  If a call C has two or more parameters of mode in out or out that are
3531       --  of an elementary type, then the call is legal only if for each name
3532       --  N that is passed as a parameter of mode in out or out to the call C,
3533       --  there is no other name among the other parameters of mode in out or
3534       --  out to C that is known to denote the same object (RM 6.4.1(6.15/3))
3535 
3536       --  If appropriate warning switch is set, we also report warnings on
3537       --  overlapping parameters that are record types or array types.
3538 
3539       Form1 := First_Formal (Subp);
3540       Act1  := First_Actual (N);
3541       while Present (Form1) and then Present (Act1) loop
3542          if Is_Covered_Formal (Form1) then
3543             Form2 := First_Formal (Subp);
3544             Act2  := First_Actual (N);
3545             while Present (Form2) and then Present (Act2) loop
3546                if Form1 /= Form2
3547                  and then Is_Covered_Formal (Form2)
3548                  and then Refer_Same_Object (Act1, Act2)
3549                then
3550                   --  Guard against previous errors
3551 
3552                   if Error_Posted (N)
3553                     or else No (Etype (Act1))
3554                     or else No (Etype (Act2))
3555                   then
3556                      null;
3557 
3558                   --  If the actual is a function call in prefix notation,
3559                   --  there is no real overlap.
3560 
3561                   elsif Nkind (Act2) = N_Function_Call then
3562                      null;
3563 
3564                   --  If type is not by-copy, assume that aliasing is intended
3565 
3566                   elsif
3567                     Present (Underlying_Type (Etype (Form1)))
3568                       and then
3569                         (Is_By_Reference_Type (Underlying_Type (Etype (Form1)))
3570                           or else
3571                             Convention (Underlying_Type (Etype (Form1))) =
3572                                               Convention_Ada_Pass_By_Reference)
3573                   then
3574                      null;
3575 
3576                   --  Under Ada 2012 we only report warnings on overlapping
3577                   --  arrays and record types if switch is set.
3578 
3579                   elsif Ada_Version >= Ada_2012
3580                     and then not Is_Elementary_Type (Etype (Form1))
3581                     and then not Warn_On_Overlap
3582                   then
3583                      null;
3584 
3585                   --  Here we may need to issue overlap message
3586 
3587                   else
3588                      Error_Msg_Warn :=
3589 
3590                        --  Overlap checking is an error only in Ada 2012. For
3591                        --  earlier versions of Ada, this is a warning.
3592 
3593                        Ada_Version < Ada_2012
3594 
3595                        --  Overlap is only illegal in Ada 2012 in the case of
3596                        --  elementary types (passed by copy). For other types,
3597                        --  we always have a warning in all Ada versions.
3598 
3599                        or else not Is_Elementary_Type (Etype (Form1))
3600 
3601                        --  Finally, debug flag -gnatd.E changes the error to a
3602                        --  warning even in Ada 2012 mode.
3603 
3604                        or else Error_To_Warning;
3605 
3606                      declare
3607                         Act  : Node_Id;
3608                         Form : Entity_Id;
3609 
3610                      begin
3611                         --  Find matching actual
3612 
3613                         Act  := First_Actual (N);
3614                         Form := First_Formal (Subp);
3615                         while Act /= Act2 loop
3616                            Next_Formal (Form);
3617                            Next_Actual (Act);
3618                         end loop;
3619 
3620                         if Is_Elementary_Type (Etype (Act1))
3621                           and then Ekind (Form2) = E_In_Parameter
3622                         then
3623                            null;  --  No real aliasing
3624 
3625                         elsif Is_Elementary_Type (Etype (Act2))
3626                           and then Ekind (Form2) = E_In_Parameter
3627                         then
3628                            null;  --  Ditto
3629 
3630                         --  If the call was written in prefix notation, and
3631                         --  thus its prefix before rewriting was a selected
3632                         --  component, count only visible actuals in the call.
3633 
3634                         elsif Is_Entity_Name (First_Actual (N))
3635                           and then Nkind (Original_Node (N)) = Nkind (N)
3636                           and then Nkind (Name (Original_Node (N))) =
3637                                                          N_Selected_Component
3638                           and then
3639                             Is_Entity_Name (Prefix (Name (Original_Node (N))))
3640                           and then
3641                             Entity (Prefix (Name (Original_Node (N)))) =
3642                               Entity (First_Actual (N))
3643                         then
3644                            if Act1 = First_Actual (N) then
3645                               Error_Msg_FE
3646                                 ("<<`IN OUT` prefix overlaps with "
3647                                  & "actual for&", Act1, Form);
3648 
3649                            else
3650                               --  For greater clarity, give name of formal
3651 
3652                               Error_Msg_Node_2 := Form;
3653                               Error_Msg_FE
3654                                 ("<<writable actual for & overlaps with "
3655                                  & "actual for&", Act1, Form);
3656                            end if;
3657 
3658                         else
3659                            --  For greater clarity, give name of formal
3660 
3661                            Error_Msg_Node_2 := Form;
3662 
3663                            --  This is one of the messages
3664 
3665                            Error_Msg_FE
3666                              ("<<writable actual for & overlaps with "
3667                               & "actual for&", Act1, Form1);
3668                         end if;
3669                      end;
3670                   end if;
3671 
3672                   return;
3673                end if;
3674 
3675                Next_Formal (Form2);
3676                Next_Actual (Act2);
3677             end loop;
3678          end if;
3679 
3680          Next_Formal (Form1);
3681          Next_Actual (Act1);
3682       end loop;
3683    end Warn_On_Overlapping_Actuals;
3684 
3685    ------------------------------
3686    -- Warn_On_Suspicious_Index --
3687    ------------------------------
3688 
3689    procedure Warn_On_Suspicious_Index (Name : Entity_Id; X : Node_Id) is
3690 
3691       Low_Bound : Uint;
3692       --  Set to lower bound for a suspicious type
3693 
3694       Ent : Entity_Id;
3695       --  Entity for array reference
3696 
3697       Typ : Entity_Id;
3698       --  Array type
3699 
3700       function Is_Suspicious_Type (Typ : Entity_Id) return Boolean;
3701       --  Tests to see if Typ is a type for which we may have a suspicious
3702       --  index, namely an unconstrained array type, whose lower bound is
3703       --  either zero or one. If so, True is returned, and Low_Bound is set
3704       --  to this lower bound. If not, False is returned, and Low_Bound is
3705       --  undefined on return.
3706       --
3707       --  For now, we limit this to standard string types, so any other
3708       --  unconstrained types return False. We may change our minds on this
3709       --  later on, but strings seem the most important case.
3710 
3711       procedure Test_Suspicious_Index;
3712       --  Test if index is of suspicious type and if so, generate warning
3713 
3714       ------------------------
3715       -- Is_Suspicious_Type --
3716       ------------------------
3717 
3718       function Is_Suspicious_Type (Typ : Entity_Id) return Boolean is
3719          LB : Node_Id;
3720 
3721       begin
3722          if Is_Array_Type (Typ)
3723            and then not Is_Constrained (Typ)
3724            and then Number_Dimensions (Typ) = 1
3725            and then Is_Standard_String_Type (Typ)
3726            and then not Has_Warnings_Off (Typ)
3727          then
3728             LB := Type_Low_Bound (Etype (First_Index (Typ)));
3729 
3730             if Compile_Time_Known_Value (LB) then
3731                Low_Bound := Expr_Value (LB);
3732                return Low_Bound = Uint_0 or else Low_Bound = Uint_1;
3733             end if;
3734          end if;
3735 
3736          return False;
3737       end Is_Suspicious_Type;
3738 
3739       ---------------------------
3740       -- Test_Suspicious_Index --
3741       ---------------------------
3742 
3743       procedure Test_Suspicious_Index is
3744 
3745          function Length_Reference (N : Node_Id) return Boolean;
3746          --  Check if node N is of the form Name'Length
3747 
3748          procedure Warn1;
3749          --  Generate first warning line
3750 
3751          ----------------------
3752          -- Length_Reference --
3753          ----------------------
3754 
3755          function Length_Reference (N : Node_Id) return Boolean is
3756             R : constant Node_Id := Original_Node (N);
3757          begin
3758             return
3759               Nkind (R) = N_Attribute_Reference
3760                 and then Attribute_Name (R) = Name_Length
3761                 and then Is_Entity_Name (Prefix (R))
3762                 and then Entity (Prefix (R)) = Ent;
3763          end Length_Reference;
3764 
3765          -----------
3766          -- Warn1 --
3767          -----------
3768 
3769          procedure Warn1 is
3770          begin
3771             Error_Msg_Uint_1 := Low_Bound;
3772             Error_Msg_FE -- CODEFIX
3773               ("?w?index for& may assume lower bound of^", X, Ent);
3774          end Warn1;
3775 
3776       --  Start of processing for Test_Suspicious_Index
3777 
3778       begin
3779          --  Nothing to do if subscript does not come from source (we don't
3780          --  want to give garbage warnings on compiler expanded code, e.g. the
3781          --  loops generated for slice assignments. Such junk warnings would
3782          --  be placed on source constructs with no subscript in sight).
3783 
3784          if not Comes_From_Source (Original_Node (X)) then
3785             return;
3786          end if;
3787 
3788          --  Case where subscript is a constant integer
3789 
3790          if Nkind (X) = N_Integer_Literal then
3791             Warn1;
3792 
3793             --  Case where original form of subscript is an integer literal
3794 
3795             if Nkind (Original_Node (X)) = N_Integer_Literal then
3796                if Intval (X) = Low_Bound then
3797                   Error_Msg_FE -- CODEFIX
3798                     ("\?w?suggested replacement: `&''First`", X, Ent);
3799                else
3800                   Error_Msg_Uint_1 := Intval (X) - Low_Bound;
3801                   Error_Msg_FE -- CODEFIX
3802                     ("\?w?suggested replacement: `&''First + ^`", X, Ent);
3803 
3804                end if;
3805 
3806             --  Case where original form of subscript is more complex
3807 
3808             else
3809                --  Build string X'First - 1 + expression where the expression
3810                --  is the original subscript. If the expression starts with "1
3811                --  + ", then the "- 1 + 1" is elided.
3812 
3813                Error_Msg_String (1 .. 13) := "'First - 1 + ";
3814                Error_Msg_Strlen := 13;
3815 
3816                declare
3817                   Sref : Source_Ptr := Sloc (First_Node (Original_Node (X)));
3818                   Tref : constant Source_Buffer_Ptr :=
3819                            Source_Text (Get_Source_File_Index (Sref));
3820                   --  Tref (Sref) is used to scan the subscript
3821 
3822                   Pctr : Natural;
3823                   --  Parentheses counter when scanning subscript
3824 
3825                begin
3826                   --  Tref (Sref) points to start of subscript
3827 
3828                   --  Elide - 1 if subscript starts with 1 +
3829 
3830                   if Tref (Sref .. Sref + 2) = "1 +" then
3831                      Error_Msg_Strlen := Error_Msg_Strlen - 6;
3832                      Sref := Sref + 2;
3833 
3834                   elsif Tref (Sref .. Sref + 1) = "1+" then
3835                      Error_Msg_Strlen := Error_Msg_Strlen - 6;
3836                      Sref := Sref + 1;
3837                   end if;
3838 
3839                   --  Now we will copy the subscript to the string buffer
3840 
3841                   Pctr := 0;
3842                   loop
3843                      --  Count parens, exit if terminating right paren. Note
3844                      --  check to ignore paren appearing as character literal.
3845 
3846                      if Tref (Sref + 1) = '''
3847                           and then
3848                         Tref (Sref - 1) = '''
3849                      then
3850                         null;
3851                      else
3852                         if Tref (Sref) = '(' then
3853                            Pctr := Pctr + 1;
3854                         elsif Tref (Sref) = ')' then
3855                            exit when Pctr = 0;
3856                            Pctr := Pctr - 1;
3857                         end if;
3858                      end if;
3859 
3860                      --  Done if terminating double dot (slice case)
3861 
3862                      exit when Pctr = 0
3863                        and then (Tref (Sref .. Sref + 1) = ".."
3864                                    or else
3865                                  Tref (Sref .. Sref + 2) = " ..");
3866 
3867                      --  Quit if we have hit EOF character, something wrong
3868 
3869                      if Tref (Sref) = EOF then
3870                         return;
3871                      end if;
3872 
3873                      --  String literals are too much of a pain to handle
3874 
3875                      if Tref (Sref) = '"' or else Tref (Sref) = '%' then
3876                         return;
3877                      end if;
3878 
3879                      --  If we have a 'Range reference, then this is a case
3880                      --  where we cannot easily give a replacement. Don't try.
3881 
3882                      if Tref (Sref .. Sref + 4) = "range"
3883                        and then Tref (Sref - 1) < 'A'
3884                        and then Tref (Sref + 5) < 'A'
3885                      then
3886                         return;
3887                      end if;
3888 
3889                      --  Else store next character
3890 
3891                      Error_Msg_Strlen := Error_Msg_Strlen + 1;
3892                      Error_Msg_String (Error_Msg_Strlen) := Tref (Sref);
3893                      Sref := Sref + 1;
3894 
3895                      --  If we get more than 40 characters then the expression
3896                      --  is too long to copy, or something has gone wrong. In
3897                      --  either case, just skip the attempt at a suggested fix.
3898 
3899                      if Error_Msg_Strlen > 40 then
3900                         return;
3901                      end if;
3902                   end loop;
3903                end;
3904 
3905                --  Replacement subscript is now in string buffer
3906 
3907                Error_Msg_FE -- CODEFIX
3908                  ("\?w?suggested replacement: `&~`", Original_Node (X), Ent);
3909             end if;
3910 
3911          --  Case where subscript is of the form X'Length
3912 
3913          elsif Length_Reference (X) then
3914             Warn1;
3915             Error_Msg_Node_2 := Ent;
3916             Error_Msg_FE
3917               ("\?w?suggest replacement of `&''Length` by `&''Last`",
3918                X, Ent);
3919 
3920          --  Case where subscript is of the form X'Length - expression
3921 
3922          elsif Nkind (X) = N_Op_Subtract
3923            and then Length_Reference (Left_Opnd (X))
3924          then
3925             Warn1;
3926             Error_Msg_Node_2 := Ent;
3927             Error_Msg_FE
3928               ("\?w?suggest replacement of `&''Length` by `&''Last`",
3929                Left_Opnd (X), Ent);
3930          end if;
3931       end Test_Suspicious_Index;
3932 
3933    --  Start of processing for Warn_On_Suspicious_Index
3934 
3935    begin
3936       --  Only process if warnings activated
3937 
3938       if Warn_On_Assumed_Low_Bound then
3939 
3940          --  Test if array is simple entity name
3941 
3942          if Is_Entity_Name (Name) then
3943 
3944             --  Test if array is parameter of unconstrained string type
3945 
3946             Ent := Entity (Name);
3947             Typ := Etype (Ent);
3948 
3949             if Is_Formal (Ent)
3950               and then Is_Suspicious_Type (Typ)
3951               and then not Low_Bound_Tested (Ent)
3952             then
3953                Test_Suspicious_Index;
3954             end if;
3955          end if;
3956       end if;
3957    end Warn_On_Suspicious_Index;
3958 
3959    -------------------------------
3960    -- Warn_On_Suspicious_Update --
3961    -------------------------------
3962 
3963    procedure Warn_On_Suspicious_Update (N : Node_Id) is
3964       Par : constant Node_Id := Parent (N);
3965       Arg : Node_Id;
3966 
3967    begin
3968       --  Only process if warnings activated
3969 
3970       if Warn_On_Suspicious_Contract then
3971          if Nkind_In (Par, N_Op_Eq, N_Op_Ne) then
3972             if N = Left_Opnd (Par) then
3973                Arg := Right_Opnd (Par);
3974             else
3975                Arg := Left_Opnd (Par);
3976             end if;
3977 
3978             if Same_Object (Prefix (N), Arg) then
3979                if Nkind (Par) = N_Op_Eq then
3980                   Error_Msg_N
3981                     ("suspicious equality test with modified version of "
3982                      & "same object?T?", Par);
3983                else
3984                   Error_Msg_N
3985                     ("suspicious inequality test with modified version of "
3986                      & "same object?T?", Par);
3987                end if;
3988             end if;
3989          end if;
3990       end if;
3991    end Warn_On_Suspicious_Update;
3992 
3993    --------------------------------------
3994    -- Warn_On_Unassigned_Out_Parameter --
3995    --------------------------------------
3996 
3997    procedure Warn_On_Unassigned_Out_Parameter
3998      (Return_Node : Node_Id;
3999       Scope_Id    : Entity_Id)
4000    is
4001       Form  : Entity_Id;
4002       Form2 : Entity_Id;
4003 
4004    begin
4005       --  Ignore if procedure or return statement does not come from source
4006 
4007       if not Comes_From_Source (Scope_Id)
4008         or else not Comes_From_Source (Return_Node)
4009       then
4010          return;
4011       end if;
4012 
4013       --  Loop through formals
4014 
4015       Form := First_Formal (Scope_Id);
4016       while Present (Form) loop
4017 
4018          --  We are only interested in OUT parameters that come from source
4019          --  and are never set in the source, and furthermore only in scalars
4020          --  since non-scalars generate too many false positives.
4021 
4022          if Ekind (Form) = E_Out_Parameter
4023            and then Never_Set_In_Source_Check_Spec (Form)
4024            and then Is_Scalar_Type (Etype (Form))
4025            and then not Present (Unset_Reference (Form))
4026          then
4027             --  Before we issue the warning, an add ad hoc defence against the
4028             --  most common case of false positives with this warning which is
4029             --  the case where there is a Boolean OUT parameter that has been
4030             --  set, and whose meaning is "ignore the values of the other
4031             --  parameters". We can't of course reliably tell this case at
4032             --  compile time, but the following test kills a lot of false
4033             --  positives, without generating a significant number of false
4034             --  negatives (missed real warnings).
4035 
4036             Form2 := First_Formal (Scope_Id);
4037             while Present (Form2) loop
4038                if Ekind (Form2) = E_Out_Parameter
4039                  and then Root_Type (Etype (Form2)) = Standard_Boolean
4040                  and then not Never_Set_In_Source_Check_Spec (Form2)
4041                then
4042                   return;
4043                end if;
4044 
4045                Next_Formal (Form2);
4046             end loop;
4047 
4048             --  Here all conditions are met, record possible unset reference
4049 
4050             Set_Unset_Reference (Form, Return_Node);
4051          end if;
4052 
4053          Next_Formal (Form);
4054       end loop;
4055    end Warn_On_Unassigned_Out_Parameter;
4056 
4057    ---------------------------------
4058    -- Warn_On_Unreferenced_Entity --
4059    ---------------------------------
4060 
4061    procedure Warn_On_Unreferenced_Entity
4062      (Spec_E : Entity_Id;
4063       Body_E : Entity_Id := Empty)
4064    is
4065       E : Entity_Id := Spec_E;
4066 
4067    begin
4068       if not Referenced_Check_Spec (E)
4069         and then not Has_Pragma_Unreferenced_Check_Spec (E)
4070         and then not Warnings_Off_Check_Spec (E)
4071         and then not Has_Junk_Name (Spec_E)
4072         and then not Is_Exported (Spec_E)
4073       then
4074          case Ekind (E) is
4075             when E_Variable =>
4076 
4077                --  Case of variable that is assigned but not read. We suppress
4078                --  the message if the variable is volatile, has an address
4079                --  clause, is aliased, or is a renaming, or is imported.
4080 
4081                if Referenced_As_LHS_Check_Spec (E)
4082                  and then No (Address_Clause (E))
4083                  and then not Is_Volatile (E)
4084                then
4085                   if Warn_On_Modified_Unread
4086                     and then not Is_Imported (E)
4087                     and then not Is_Aliased (E)
4088                     and then No (Renamed_Object (E))
4089                   then
4090                      if not Has_Pragma_Unmodified_Check_Spec (E) then
4091                         Error_Msg_N -- CODEFIX
4092                           ("?u?variable & is assigned but never read!", E);
4093                      end if;
4094 
4095                      Set_Last_Assignment (E, Empty);
4096                   end if;
4097 
4098                --  Normal case of neither assigned nor read (exclude variables
4099                --  referenced as out parameters, since we already generated
4100                --  appropriate warnings at the call point in this case).
4101 
4102                elsif not Referenced_As_Out_Parameter (E) then
4103 
4104                   --  We suppress the message for types for which a valid
4105                   --  pragma Unreferenced_Objects has been given, otherwise
4106                   --  we go ahead and give the message.
4107 
4108                   if not Has_Pragma_Unreferenced_Objects (Etype (E)) then
4109 
4110                      --  Distinguish renamed case in message
4111 
4112                      if Present (Renamed_Object (E))
4113                        and then Comes_From_Source (Renamed_Object (E))
4114                      then
4115                         Error_Msg_N -- CODEFIX
4116                           ("?u?renamed variable & is not referenced!", E);
4117                      else
4118                         Error_Msg_N -- CODEFIX
4119                           ("?u?variable & is not referenced!", E);
4120                      end if;
4121                   end if;
4122                end if;
4123 
4124             when E_Constant =>
4125                if not Has_Pragma_Unreferenced_Objects (Etype (E)) then
4126                   if Present (Renamed_Object (E))
4127                     and then Comes_From_Source (Renamed_Object (E))
4128                   then
4129                      Error_Msg_N -- CODEFIX
4130                        ("?u?renamed constant & is not referenced!", E);
4131                   else
4132                      Error_Msg_N -- CODEFIX
4133                        ("?u?constant & is not referenced!", E);
4134                   end if;
4135                end if;
4136 
4137             when E_In_Parameter     |
4138                  E_In_Out_Parameter =>
4139 
4140                --  Do not emit message for formals of a renaming, because
4141                --  they are never referenced explicitly.
4142 
4143                if Nkind (Original_Node (Unit_Declaration_Node (Scope (E)))) /=
4144                                           N_Subprogram_Renaming_Declaration
4145                then
4146                   --  Suppress this message for an IN OUT parameter of a
4147                   --  non-scalar type, since it is normal to have only an
4148                   --  assignment in such a case.
4149 
4150                   if Ekind (E) = E_In_Parameter
4151                     or else not Referenced_As_LHS_Check_Spec (E)
4152                     or else Is_Scalar_Type (Etype (E))
4153                   then
4154                      if Present (Body_E) then
4155                         E := Body_E;
4156                      end if;
4157 
4158                      if not Is_Trivial_Subprogram (Scope (E)) then
4159                         Error_Msg_NE -- CODEFIX
4160                           ("?u?formal parameter & is not referenced!",
4161                            E, Spec_E);
4162                      end if;
4163                   end if;
4164                end if;
4165 
4166             when E_Out_Parameter =>
4167                null;
4168 
4169             when E_Discriminant =>
4170                Error_Msg_N ("?u?discriminant & is not referenced!", E);
4171 
4172             when E_Named_Integer |
4173                  E_Named_Real    =>
4174                Error_Msg_N -- CODEFIX
4175                  ("?u?named number & is not referenced!", E);
4176 
4177             when Formal_Object_Kind =>
4178                Error_Msg_N -- CODEFIX
4179                  ("?u?formal object & is not referenced!", E);
4180 
4181             when E_Enumeration_Literal =>
4182                Error_Msg_N -- CODEFIX
4183                  ("?u?literal & is not referenced!", E);
4184 
4185             when E_Function =>
4186                Error_Msg_N -- CODEFIX
4187                  ("?u?function & is not referenced!", E);
4188 
4189             when E_Procedure =>
4190                Error_Msg_N -- CODEFIX
4191                  ("?u?procedure & is not referenced!", E);
4192 
4193             when E_Package =>
4194                Error_Msg_N -- CODEFIX
4195                  ("?u?package & is not referenced!", E);
4196 
4197             when E_Exception =>
4198                Error_Msg_N -- CODEFIX
4199                  ("?u?exception & is not referenced!", E);
4200 
4201             when E_Label =>
4202                Error_Msg_N -- CODEFIX
4203                  ("?u?label & is not referenced!", E);
4204 
4205             when E_Generic_Procedure =>
4206                Error_Msg_N -- CODEFIX
4207                  ("?u?generic procedure & is never instantiated!", E);
4208 
4209             when E_Generic_Function =>
4210                Error_Msg_N -- CODEFIX
4211                  ("?u?generic function & is never instantiated!", E);
4212 
4213             when Type_Kind =>
4214                Error_Msg_N -- CODEFIX
4215                  ("?u?type & is not referenced!", E);
4216 
4217             when others =>
4218                Error_Msg_N -- CODEFIX
4219                  ("?u?& is not referenced!", E);
4220          end case;
4221 
4222          --  Kill warnings on the entity on which the message has been posted
4223          --  (nothing is posted on out parameters because back end might be
4224          --  able to uncover an uninitialized path, and warn accordingly).
4225 
4226          if Ekind (E) /= E_Out_Parameter then
4227             Set_Warnings_Off (E);
4228          end if;
4229       end if;
4230    end Warn_On_Unreferenced_Entity;
4231 
4232    --------------------------------
4233    -- Warn_On_Useless_Assignment --
4234    --------------------------------
4235 
4236    procedure Warn_On_Useless_Assignment
4237      (Ent : Entity_Id;
4238       N   : Node_Id := Empty)
4239    is
4240       P    : Node_Id;
4241       X    : Node_Id;
4242 
4243       function Check_Ref (N : Node_Id) return Traverse_Result;
4244       --  Used to instantiate Traverse_Func. Returns Abandon if a reference to
4245       --  the entity in question is found.
4246 
4247       function Test_No_Refs is new Traverse_Func (Check_Ref);
4248 
4249       ---------------
4250       -- Check_Ref --
4251       ---------------
4252 
4253       function Check_Ref (N : Node_Id) return Traverse_Result is
4254       begin
4255          --  Check reference to our identifier. We use name equality here
4256          --  because the exception handlers have not yet been analyzed. This
4257          --  is not quite right, but it really does not matter that we fail
4258          --  to output the warning in some obscure cases of name clashes.
4259 
4260          if Nkind (N) = N_Identifier and then Chars (N) = Chars (Ent) then
4261             return Abandon;
4262          else
4263             return OK;
4264          end if;
4265       end Check_Ref;
4266 
4267    --  Start of processing for Warn_On_Useless_Assignment
4268 
4269    begin
4270       --  Check if this is a case we want to warn on, a scalar or access
4271       --  variable with the last assignment field set, with warnings enabled,
4272       --  and which is not imported or exported. We also check that it is OK
4273       --  to capture the value. We are not going to capture any value, but
4274       --  the warning message depends on the same kind of conditions.
4275 
4276       if Is_Assignable (Ent)
4277         and then not Is_Return_Object (Ent)
4278         and then Present (Last_Assignment (Ent))
4279         and then not Is_Imported (Ent)
4280         and then not Is_Exported (Ent)
4281         and then Safe_To_Capture_Value (N, Ent)
4282         and then not Has_Pragma_Unreferenced_Check_Spec (Ent)
4283         and then not Has_Junk_Name (Ent)
4284       then
4285          --  Before we issue the message, check covering exception handlers.
4286          --  Search up tree for enclosing statement sequences and handlers.
4287 
4288          P := Parent (Last_Assignment (Ent));
4289          while Present (P) loop
4290 
4291             --  Something is really wrong if we don't find a handled statement
4292             --  sequence, so just suppress the warning.
4293 
4294             if No (P) then
4295                Set_Last_Assignment (Ent, Empty);
4296                return;
4297 
4298             --  When we hit a package/subprogram body, issue warning and exit
4299 
4300             elsif Nkind_In (P, N_Entry_Body,
4301                                N_Package_Body,
4302                                N_Subprogram_Body,
4303                                N_Task_Body)
4304             then
4305                --  Case of assigned value never referenced
4306 
4307                if No (N) then
4308                   declare
4309                      LA : constant Node_Id := Last_Assignment (Ent);
4310 
4311                   begin
4312                      --  Don't give this for OUT and IN OUT formals, since
4313                      --  clearly caller may reference the assigned value. Also
4314                      --  never give such warnings for internal variables.
4315 
4316                      if Ekind (Ent) = E_Variable
4317                        and then not Is_Internal_Name (Chars (Ent))
4318                      then
4319                         --  Give appropriate message, distinguishing between
4320                         --  assignment statements and out parameters.
4321 
4322                         if Nkind_In (Parent (LA), N_Procedure_Call_Statement,
4323                                                   N_Parameter_Association)
4324                         then
4325                            Error_Msg_NE
4326                              ("?m?& modified by call, but value never "
4327                               & "referenced", LA, Ent);
4328 
4329                         else
4330                            Error_Msg_NE -- CODEFIX
4331                              ("?m?useless assignment to&, value never "
4332                               & "referenced!", LA, Ent);
4333                         end if;
4334                      end if;
4335                   end;
4336 
4337                --  Case of assigned value overwritten
4338 
4339                else
4340                   declare
4341                      LA : constant Node_Id := Last_Assignment (Ent);
4342 
4343                   begin
4344                      Error_Msg_Sloc := Sloc (N);
4345 
4346                      --  Give appropriate message, distinguishing between
4347                      --  assignment statements and out parameters.
4348 
4349                      if Nkind_In (Parent (LA), N_Procedure_Call_Statement,
4350                                                N_Parameter_Association)
4351                      then
4352                         Error_Msg_NE
4353                           ("?m?& modified by call, but value overwritten #!",
4354                            LA, Ent);
4355                      else
4356                         Error_Msg_NE -- CODEFIX
4357                           ("?m?useless assignment to&, value overwritten #!",
4358                            LA, Ent);
4359                      end if;
4360                   end;
4361                end if;
4362 
4363                --  Clear last assignment indication and we are done
4364 
4365                Set_Last_Assignment (Ent, Empty);
4366                return;
4367 
4368             --  Enclosing handled sequence of statements
4369 
4370             elsif Nkind (P) = N_Handled_Sequence_Of_Statements then
4371 
4372                --  Check exception handlers present
4373 
4374                if Present (Exception_Handlers (P)) then
4375 
4376                   --  If we are not at the top level, we regard an inner
4377                   --  exception handler as a decisive indicator that we should
4378                   --  not generate the warning, since the variable in question
4379                   --  may be accessed after an exception in the outer block.
4380 
4381                   if not Nkind_In (Parent (P), N_Entry_Body,
4382                                                N_Package_Body,
4383                                                N_Subprogram_Body,
4384                                                N_Task_Body)
4385                   then
4386                      Set_Last_Assignment (Ent, Empty);
4387                      return;
4388 
4389                      --  Otherwise we are at the outer level. An exception
4390                      --  handler is significant only if it references the
4391                      --  variable in question, or if the entity in question
4392                      --  is an OUT or IN OUT parameter, which which case
4393                      --  the caller can reference it after the exception
4394                      --  handler completes.
4395 
4396                   else
4397                      if Is_Formal (Ent) then
4398                         Set_Last_Assignment (Ent, Empty);
4399                         return;
4400 
4401                      else
4402                         X := First (Exception_Handlers (P));
4403                         while Present (X) loop
4404                            if Test_No_Refs (X) = Abandon then
4405                               Set_Last_Assignment (Ent, Empty);
4406                               return;
4407                            end if;
4408 
4409                            X := Next (X);
4410                         end loop;
4411                      end if;
4412                   end if;
4413                end if;
4414             end if;
4415 
4416             P := Parent (P);
4417          end loop;
4418       end if;
4419    end Warn_On_Useless_Assignment;
4420 
4421    ---------------------------------
4422    -- Warn_On_Useless_Assignments --
4423    ---------------------------------
4424 
4425    procedure Warn_On_Useless_Assignments (E : Entity_Id) is
4426       Ent : Entity_Id;
4427 
4428    begin
4429       Process_Deferred_References;
4430 
4431       if Warn_On_Modified_Unread
4432         and then In_Extended_Main_Source_Unit (E)
4433       then
4434          Ent := First_Entity (E);
4435          while Present (Ent) loop
4436             Warn_On_Useless_Assignment (Ent);
4437             Next_Entity (Ent);
4438          end loop;
4439       end if;
4440    end Warn_On_Useless_Assignments;
4441 
4442    -----------------------------
4443    -- Warnings_Off_Check_Spec --
4444    -----------------------------
4445 
4446    function Warnings_Off_Check_Spec (E : Entity_Id) return Boolean is
4447    begin
4448       if Is_Formal (E) and then Present (Spec_Entity (E)) then
4449 
4450          --  Note: use of OR here instead of OR ELSE is deliberate, we want
4451          --  to mess with flags on both entities.
4452 
4453          return Has_Warnings_Off (E)
4454                   or
4455                 Has_Warnings_Off (Spec_Entity (E));
4456 
4457       else
4458          return Has_Warnings_Off (E);
4459       end if;
4460    end Warnings_Off_Check_Spec;
4461 
4462 end Sem_Warn;